let
    fx = (file) =>
        [s = Excel.Workbook(file, null, true){[Item="1x2",Kind="Sheet"]}[Data],
        skip = Table.RemoveLastN(s, (x) => x[Column2] is null),
        pzz = List.Buffer({0, 1, 2} & List.PositionOf(Record.ToList(skip{0}), null, Occurrence.All, (c, v) => c <> v)),
        lst = List.Buffer(Table.ToList(skip, (x) => List.Transform(pzz, (i) => x{i}))),
        headers = List.Transform(
            List.Zip({List.Skip(lst{0}, 3), List.Transform(List.Skip(lst{1}, 3), Text.From)}),
            (x) => Text.Combine(x, " ")
        ),
        to_table = Table.FromRows(List.Skip(lst, 2), {"date", "home", "guest"} & headers)][to_table],
    // column names
    names = {"winline", "melbetru"}, // дополните список руками или прочитайте из файла
    columns = {"date", "home", "guest"} & List.Transform(
        List.Zip(
            {
                List.Combine(List.Transform(names, (x) => List.Repeat({x}, 3))),
                List.Repeat({" 1", " X", " 2"}, List.Count(names))
            }
        ),
        Text.Combine
    ),
    files = Table.SelectRows(
        Folder.Files("ПУТЬ_К_ПАПКЕ_С_ФАЙЛАМИ"),
        (x) => x[Attributes][Kind] = "Excel File" and x[Attributes][Hidden] = false
    )[[Name], [Content]],
    tx_files = Table.TransformColumns(files, {"Content", fx}),
    z = Table.ExpandTableColumn(tx_files, "Content", columns)
in
    z