Option Explicit
Public Const GENERIC_READ = &H80000000
Public Const FILE_SHARE_READ = &H1
Public Const OPEN_EXISTING = 3
Public Const FILE_ATTRIBUTE_ARCHIVE = &H20

Type SYSTEMTIME
     wYear As Integer
     wMonth As Integer
     wDayOfWeek As Integer
     wDay As Integer
     wHour As Integer
     wMinute As Integer
     wSecond As Integer
     wMilliseconds As Integer
End Type

Type FILETIME
     dwLowDateTime As Long
     dwHighDateTime As Long
End Type

Declare Function CreateFile Lib "kernel32.dll" Alias "CreateFileA" ( _
                    ByVal lpFileName As String, _
                    ByVal dwDesiredAccess As Long, _
                    ByVal dwShareMode As Long, _
                    lpSecurityAttributes As Any, _
                    ByVal dwCreationDisposition As Long, _
                    ByVal dwFlagsAndAttributes As Long, _
                    ByVal hTemplateFile As Long) As Long

Declare Function GetFileTime Lib "kernel32" ( _
                     ByVal hFile As Long, _
                     lpCreationTime As FILETIME, _
                     lpLastAccessTime As FILETIME, _
                     lpLastWriteTime As FILETIME) As Long

Declare Function FileTimeToLocalFileTime Lib "kernel32.dll" ( _
                     lpFileTime As FILETIME, _
                     lpLocalFileTime As FILETIME) As Long

Declare Function FileTimeToSystemTime Lib "kernel32.dll" ( _
                     lpFileTime As FILETIME, _
                     lpSystemTime As SYSTEMTIME) As Long

Declare Function CloseHandle Lib "kernel32.dll" ( _
                     ByVal hObject As Long) As Long

Sub a()
     ' Display the date on which the file C:\MyApp\test.txt was
     ' created.  Note how the time zone conversion is necessary.
     Dim hFile As Long  ' handle to the opened file
     Dim cTime As FILETIME  ' receives time of creation
     Dim aTime As FILETIME  ' receives time of last access
     Dim mTime As FILETIME  ' receives time of last modification
     Dim theTime As SYSTEMTIME  ' used to manipulate the time
     Dim retval As Long  ' return value

     ' First, open the file C:\MyApp\test.txt for read-level access.  Note the
     ' expression necessary to pass 0 as lpSecurityAttributes.
     hFile = CreateFile("C:\MyApp\test.txt", _
                        GENERIC_READ, _
                        FILE_SHARE_READ, _
                        ByVal CLng(0), _
                        OPEN_EXISTING, _
                        FILE_ATTRIBUTE_ARCHIVE, 0)
     If hFile = -1 Then
        Debug.Print "Could not open the file successfully -- aborting."
        End  ' terminate the program
     End If

     ' Next, get the creation, last-access, and last-modification times.
     retval = GetFileTime(hFile, cTime, aTime, mTime)
     ' Convert the last-modification time to the local time zone.
     retval = FileTimeToLocalFileTime(mTime, mTime)
     ' Convert the FILETIME format to the SYSTEMTIME format.
     retval = FileTimeToSystemTime(mTime, theTime)

     ' Display the date of last-modification of the file to the user.
     With theTime
        Debug.Print "m "; .wDay & "." & .wMonth & "." & .wYear, _
                    .wHour & ":" & .wMinute & ":" & .wSecond

     End With

     ' Close the file to free up resources.
     retval = CloseHandle(hFile)
End Sub