Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Перевод градусов, минут и секунд в десятичные? - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Перевод градусов, минут и секунд в десятичные? (Формулы/Formulas)
Перевод градусов, минут и секунд в десятичные?
Morinus Дата: Суббота, 19.04.2014, 20:11 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Здравствуйте! Помогите пожалуйста с формулой. У меня есть данные, например: - 1° 3'31" (все в одной ячейке) и мне нужна формула для перевода этого значения в десятичные, что должно дать -1,058611111. В данном случае значения я привел со знаком "-", но в моих данных так же есть значения и со знаком "+", что формула должна понимать. Спасибо!
К сообщению приложен файл: 1918618.xls (19.0 Kb) · 4319061.xls (19.0 Kb)
 
Ответить
СообщениеЗдравствуйте! Помогите пожалуйста с формулой. У меня есть данные, например: - 1° 3'31" (все в одной ячейке) и мне нужна формула для перевода этого значения в десятичные, что должно дать -1,058611111. В данном случае значения я привел со знаком "-", но в моих данных так же есть значения и со знаком "+", что формула должна понимать. Спасибо!
Автор - Morinus
Дата добавления - 19.04.2014 в 20:11
Pelena Дата: Суббота, 19.04.2014, 21:10 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 19342
Репутация: 4522 ±
Замечаний: ±

Excel 365 & Mac Excel
Наверное, не самый оптимальный вариант
Код
=ЛЕВСИМВ(D4;ПОИСК("°";D4)-1)+(ПСТР(D4;ПОИСК("°";D4)+1;2)/60+ПСТР(D4;ПОИСК("'";D4)+1;2)/3600)*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
К сообщению приложен файл: 3741586.xls (28.0 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеНаверное, не самый оптимальный вариант
Код
=ЛЕВСИМВ(D4;ПОИСК("°";D4)-1)+(ПСТР(D4;ПОИСК("°";D4)+1;2)/60+ПСТР(D4;ПОИСК("'";D4)+1;2)/3600)*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
Автор - Pelena
Дата добавления - 19.04.2014 в 21:10
Nic70y Дата: Суббота, 19.04.2014, 21:27 | Сообщение № 3
Группа: Друзья
Ранг: Экселист
Сообщений: 8953
Репутация: 2342 ±
Замечаний: 0% ±

Excel 2010
для разнообразия:
Код
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ЛЕВБ(D4;ДЛСТР(D4)-1);"°";":");"'";":");"- ";"")*24*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)

ЮMoney 41001841029809
 
Ответить
Сообщениедля разнообразия:
Код
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ЛЕВБ(D4;ДЛСТР(D4)-1);"°";":");"'";":");"- ";"")*24*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
Автор - Nic70y
Дата добавления - 19.04.2014 в 21:27
Morinus Дата: Суббота, 19.04.2014, 21:49 | Сообщение № 4
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Круто! Спасибо Вам огромное. А можно такую же формулу только без значения секунд.
 
Ответить
СообщениеКруто! Спасибо Вам огромное. А можно такую же формулу только без значения секунд.
Автор - Morinus
Дата добавления - 19.04.2014 в 21:49
Nic70y Дата: Суббота, 19.04.2014, 21:57 | Сообщение № 5
Группа: Друзья
Ранг: Экселист
Сообщений: 8953
Репутация: 2342 ±
Замечаний: 0% ±

Excel 2010
Моя:
Код
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ЛЕВБ(D4;ДЛСТР(D4)-4);"°";":");"- ";"")*24*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
Елены:
Код
=ЛЕВСИМВ(D4;ПОИСК("°";D4)-1)+(ПСТР(D4;ПОИСК("°";D4)+1;2)/60)*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)

ЮMoney 41001841029809
 
Ответить
СообщениеМоя:
Код
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(ЛЕВБ(D4;ДЛСТР(D4)-4);"°";":");"- ";"")*24*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
Елены:
Код
=ЛЕВСИМВ(D4;ПОИСК("°";D4)-1)+(ПСТР(D4;ПОИСК("°";D4)+1;2)/60)*ЕСЛИ(ЛЕВСИМВ(D4)="-";-1;1)
Автор - Nic70y
Дата добавления - 19.04.2014 в 21:57
Rustem Дата: Суббота, 19.04.2014, 22:14 | Сообщение № 6
Группа: Проверенные
Ранг: Обитатель
Сообщений: 281
Репутация: 48 ±
Замечаний: 0% ±

Excel 2013
http://support.microsoft.com/kb/213449/ru

WMR: R183220163895
 
Ответить
Сообщениеhttp://support.microsoft.com/kb/213449/ru
Автор - Rustem
Дата добавления - 19.04.2014 в 22:14
Morinus Дата: Суббота, 19.04.2014, 22:15 | Сообщение № 7
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Благодарю respect
 
Ответить
СообщениеБлагодарю respect
Автор - Morinus
Дата добавления - 19.04.2014 в 22:15
pahanhar Дата: Суббота, 29.12.2018, 05:36 | Сообщение № 8
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Pelena, привет. можно ли подредактировать формулу под формат 58° 54' 43.783''
К сообщению приложен файл: 999.xls (29.0 Kb)
 
Ответить
СообщениеPelena, привет. можно ли подредактировать формулу под формат 58° 54' 43.783''
Автор - pahanhar
Дата добавления - 29.12.2018 в 05:36
Светлый Дата: Суббота, 29.12.2018, 06:42 | Сообщение № 9
Группа: Друзья
Ранг: Старожил
Сообщений: 1843
Репутация: 522 ±
Замечаний: 0% ±

Excel 2013, 2016
Ну и мой вариант:
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММПРОИЗВ(ПСТР(0&B4;ДЛСТР(0&B4)-{8;5;2};2)/60^{0;1;2})
*Даже так:
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММПРОИЗВ(ПСТР(0&B4;ДЛСТР(B4)-{7;4;1};2)/60^{0;1;2})

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Суббота, 29.12.2018, 07:20
 
Ответить
СообщениеНу и мой вариант:
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММПРОИЗВ(ПСТР(0&B4;ДЛСТР(0&B4)-{8;5;2};2)/60^{0;1;2})
*Даже так:
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММПРОИЗВ(ПСТР(0&B4;ДЛСТР(B4)-{7;4;1};2)/60^{0;1;2})
Автор - Светлый
Дата добавления - 29.12.2018 в 06:42
pahanhar Дата: Суббота, 29.12.2018, 09:10 | Сообщение № 10
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Светлый, здравствуйте. Мне надо перевести из 58° 54' 43.783'' в десятичные DD,DDDDD
 
Ответить
СообщениеСветлый, здравствуйте. Мне надо перевести из 58° 54' 43.783'' в десятичные DD,DDDDD
Автор - pahanhar
Дата добавления - 29.12.2018 в 09:10
AlexM Дата: Суббота, 29.12.2018, 09:21 | Сообщение № 11
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4517
Репутация: 1129 ±
Замечаний: 0% ±

Excel 2003
pahanhar, тема не ваша. ответы для Morinus
Еще вариант на основе формул Сергея (Светлый)
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММ(ЛЕВБ(ПРАВБ(0&B4;{9;6;3});2)/{1;60;3600})


Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
Сообщениеpahanhar, тема не ваша. ответы для Morinus
Еще вариант на основе формул Сергея (Светлый)
Код
=ЗНАК(ЛЕВБ(B4)&1)*СУММ(ЛЕВБ(ПРАВБ(0&B4;{9;6;3});2)/{1;60;3600})
Автор - AlexM
Дата добавления - 29.12.2018 в 09:21
Светлый Дата: Суббота, 29.12.2018, 10:32 | Сообщение № 12
Группа: Друзья
Ранг: Старожил
Сообщений: 1843
Репутация: 522 ±
Замечаний: 0% ±

Excel 2013, 2016
Здравствуйте!
Для 58° 54' 43.783''
Код
=ЗНАК(ЛЕВБ(D3)&1)*СУММПРОИЗВ(ПСТР(0&D3;ДЛСТР(D3)-{14;11;7};{2;3;7})/60^{0;1;2})
Можно так, но придётся подкорректировать, если разное начало. "- 58°"," 58°","58°". И десятичная точка может дать ошибку.
Код
=ЗНАК(ЛЕВБ(D3)&1)*СУММПРОИЗВ(ПСТР(0&ПОДСТАВИТЬ(D3;".";ПСТР(1/2;2;1));ДЛСТР(D3)-{14;11;7};{2;3;7})/60^{0;1;2})
*Или как у AlexM
Код
=ЗНАК(ЛЕВБ(D4)&1)*СУММ(ЛЕВБ(ПРАВБ(0&D4;{16;13;9});{2;3;7})/60^{0;1;2})

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Суббота, 29.12.2018, 11:03
 
Ответить
СообщениеЗдравствуйте!
Для 58° 54' 43.783''
Код
=ЗНАК(ЛЕВБ(D3)&1)*СУММПРОИЗВ(ПСТР(0&D3;ДЛСТР(D3)-{14;11;7};{2;3;7})/60^{0;1;2})
Можно так, но придётся подкорректировать, если разное начало. "- 58°"," 58°","58°". И десятичная точка может дать ошибку.
Код
=ЗНАК(ЛЕВБ(D3)&1)*СУММПРОИЗВ(ПСТР(0&ПОДСТАВИТЬ(D3;".";ПСТР(1/2;2;1));ДЛСТР(D3)-{14;11;7};{2;3;7})/60^{0;1;2})
*Или как у AlexM
Код
=ЗНАК(ЛЕВБ(D4)&1)*СУММ(ЛЕВБ(ПРАВБ(0&D4;{16;13;9});{2;3;7})/60^{0;1;2})
Автор - Светлый
Дата добавления - 29.12.2018 в 10:32
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Перевод градусов, минут и секунд в десятичные? (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!