Function getResultLine(ByVal rng As Range)
    'возвращает строку исходов матчей (фактических или прогнозных)
    Dim arr()       As Variant
    Dim arrResult() As Variant 'исходы матчей (1X2)
    Dim varSplit    As Variant
    Dim n           As Integer 'ячеек счёта в диапазоне
    Dim i           As Integer
    Dim host        As Integer 'голы хозяина
    Dim guest       As Integer 'голы гостя
    
    arr = rng.Value
    If rng.Rows.Count >= rng.Columns.Count Then
        n = rng.Rows.Count
    Else
        n = rng.Columns.Count
        arr = WorksheetFunction.Transpose(arr)
    End If
    
    ReDim arrResult(1 To n)
    For i = 1 To n
        varSplit = Split(arr(i, 1), ":")
        host = varSplit(0)
        guest = varSplit(1)
        If host > guest Then
            arrResult(i) = "1" 'победа хозяина
        ElseIf host < guest Then
            arrResult(i) = "2" 'победа гостя
        ElseIf host = guest Then
            arrResult(i) = "X" 'ничья
        End If
    Next i
    
    getResultLine = Join(arrResult, "") 'например, 111Х2Х1111
End Function

Function getGuessedItemsByString(ByVal strFact As String, ByVal strForecast As String) As String
    'возвращает строку угаданных позиций - при сравнении строк
    Dim n1      As Integer
    Dim n2      As Integer
    Dim res3    As String 'например, 111_2Х___1 - строка угаданных позиций игрока
    Dim i       As Integer
    
    n1 = Len(strFact)
    n2 = Len(strForecast)
    
    If n1 <> n2 Then
        getGuessedItemsByString = "Разная длина строк"
        Exit Function
    End If
       
    res3 = ""
    For i = 1 To n1
        If Mid(strFact, i, 1) = Mid(strForecast, i, 1) Then
            res3 = res3 & Mid(strFact, i, 1)
        Else
            res3 = res3 & "_"
        End If
    Next i
    
    getGuessedItemsByString = res3
End Function

Function getGuessedItemsByRange(ByVal rngFact As Range, ByVal rngForecast As Range) As String
    'возвращает строку угаданных позиций - при сравнении диапазонов
    Dim n1      As Integer
    Dim n2      As Integer
    Dim res1    As String 'например, 111Х2Х1111 - фактический результат
    Dim res2    As String 'например, 11122ХХ221 - прогноз игрока
    Dim res3    As String 'например, 111_2Х___1 - строка угаданных позиций игрока
    Dim i       As Integer
    
    n1 = WorksheetFunction.Max(rngFact.Rows.Count, rngFact.Columns.Count)
    n2 = WorksheetFunction.Max(rngForecast.Rows.Count, rngForecast.Columns.Count)
    
    If n1 <> n2 Then
        getGuessedItemsByRange = "Разная длина диапазонов"
        Exit Function
    End If
    
    res1 = getResultLine(rngFact)
    res2 = getResultLine(rngForecast)
    
    res3 = getGuessedItemsByString(res1, res2)
    
    getGuessedItemsByRange = res3
End Function