Sub Example()
'Count Dates
Debug.Print Application.CountA(ListDatesFromRanges_("7.05-8.05,5.01;26.03-01.04;7.05.2017-8.05.2017;29.06;29.10-02.11"))
'Count Dates 2-nd variant
Debug.Print UBound(ListDatesFromRanges_("7.05-8.05,5.01;26.03-01.04;7.05.2017-8.05.2017;29.06;29.10-02.11")) + 1
'Count Dates with the specified year
Debug.Print UBound(ListDatesFromRanges_("7.05-8.05,5.01;26.03-01.04;7.05.2017-8.05.2017;29.06;29.10-02.11", 2018)) + 1

Debug.Print vbLf
'List all Dates in all ranges
Debug.Print Join(ListDatesFromRanges_("7.05-8.05,5.01;26.03-01.04;7.05.2017-8.05.2017;29.06;29.10-02.11"), vbLf) & vbLf
'List all Dates with sorting and the specified year
Debug.Print Join(ListDatesFromRanges_("7.05-8.05,5.01;26.03-01.04;7.05.2017-8.05.2017;29.06;29.10-02.11", 2018, 1), vbLf)
End Sub
Function ListDatesFromRanges_(ByVal strListRanges As String, Optional ByVal addYear&, Optional ByVal Sort_ As Boolean) As Variant

'Made by Yaroslav Popov 26/12/2017

Dim dicRanges As New Scripting.Dictionary, dicClearRanges As New Scripting.Dictionary, dicDates As New Scripting.Dictionary, tDate As Date
Dim arr, arr1, i#, ii%
' Clear string, and convert to one format
strListRanges = Replace(strListRanges, ",", ";")
strListRanges = Replace(strListRanges, ":", "-")
strListRanges = Replace(strListRanges, " ", "")

If addYear = 0 Then addYear = Year(Now)
arr = Split(strListRanges, ";")
For i = LBound(arr) To UBound(arr)
dicRanges(Trim(arr(i))) = i
Next

arr1 = dicRanges.Keys
For i = LBound(arr1) To UBound(arr1)
    If InStr(arr1(i), ";") = 0 Then dicClearRanges(Trim(arr1(i))) = ii
Next

arr1 = dicClearRanges.Keys
For i = LBound(arr1) To UBound(arr1)
    arr = Split(arr1(i), "-")
    If UBound(arr) Then
        If Not arr(0) Like "*#.##.##*" Then arr(0) = arr(0) & "." & addYear
        If Not arr(1) Like "*#.##.##*" Then arr(1) = arr(1) & "." & addYear
            
        tDate = CDate(arr(0))
        Do Until tDate > CDate(arr(1))
            dicDates(tDate) = i
            tDate = tDate + 1
        Loop
    Else
        If Not arr(0) Like "*#.##.##*" Then arr(0) = arr(0) & "." & addYear
        dicDates(CDate(arr(0))) = i
    End If
Next
arr = dicDates.Keys
If Sort_ Then QuickSort arr, LBound(arr), UBound(arr)
If TypeName(Application.Caller) = "Range" Then
    i = Application.Caller.Cells.Count
    If i - 1 > UBound(arr) Then ReDim Preserve arr(i - 1)
End If
ListDatesFromRanges_ = arr
End Function

Sub QuickSort(arr, lo As Long, hi As Long)
  Dim varPivot As Variant
  Dim varTmp As Variant
  Dim tmpLow As Long
  Dim tmpHi As Long
  tmpLow = lo
  tmpHi = hi
  varPivot = arr((lo + hi) \ 2)
  Do While tmpLow <= tmpHi
    Do While arr(tmpLow) < varPivot And tmpLow < hi
      tmpLow = tmpLow + 1
    Loop
    Do While varPivot < arr(tmpHi) And tmpHi > lo
      tmpHi = tmpHi - 1
    Loop
    If tmpLow <= tmpHi Then
      varTmp = arr(tmpLow)
      arr(tmpLow) = arr(tmpHi)
      arr(tmpHi) = varTmp
      tmpLow = tmpLow + 1
      tmpHi = tmpHi - 1
    End If
  Loop
  If lo < tmpHi Then QuickSort arr, lo, tmpHi
  If tmpLow < hi Then QuickSort arr, tmpLow, hi
End Sub