Sub Copy_ROWs_to_EXT_FILES()   ' скопировать строки выделенных ячеек во внешние файлы-накопители
       If Not TypeName(Selection) = "Range" Then Exit Sub
      Dim lr&, wbkDEST As Workbook, i%
      Const sLocAddrCol$ = "A"   ' столбец, в ячейках которого прописан локальный (основной) путь к файлу-накопителю
      Const sNetAddrCol$ = "B"   ' столбец, в ячейках которого прописан сетевой (резервный) путь к файлу-накопителю
      Dim sLocDestPath$   ' локальный (основной) путь к файлу-накопителю
      Dim sNetDestPath$   ' сетевой (резервный) путь к файлу-накопителю
      With Application: .ScreenUpdating = False: .DisplayAlerts = False: .EnableEvents = False: End With
      For i = 1 To Selection.Rows.Count
          sLocDestPath = Range(sLocAddrCol & Selection(i, 1).Row).Value
          sNetDestPath = Range(sNetAddrCol & Selection(i, 1).Row).Value
          On Error Resume Next
          Set wbkDEST = GetObject(sLocDestPath)   ' локальный файл-накопитель
          If Err Then Err.Clear: Set wbkDEST = GetObject(sNetDestPath)   ' сетевой файл-накопитель (если нужно)
          If Err Then Err.Clear: MsgBox "Файл-накопитель не доступен!": GoTo Next_i

          lr = wbkDEST.Sheets(1).Cells(Rows.Count, 1).End(xlUp).Row
          'lr = wbkDEST.Sheets(1).UsedRange.Row + wbkDEST.Sheets(1).UsedRange.Rows.Count - 1
          Selection(i, 1).EntireRow.Copy wbkDEST.Sheets(1).Cells(lr + 1, 1)  ' копирование
          wbkDEST.Close (True)   ' закрыть с сохранением
          Windows(ThisWorkbook.Name).Visible = True
          fnDelay (3)  ' задержка
Next_i:         Next i
      With Application: .EnableEvents = True: .DisplayAlerts = True: .ScreenUpdating = True: End With
      Set wbkDEST = Nothing
End Sub

Function fnDelay(Seconds As Single)  ' задержка
      Dim Finish As Single: Finish = Timer + Seconds
      Do While Timer < Finish: DoEvents: Loop
End Function

Private Sub Workbook_Open()
Debug.Print Me.Parent.Caption
Debug.Print Application.Caption
   If Me.Parent.Caption = Application.Caption Then Windows(Me.Name).Visible = True
End Sub