@echo off

SETLOCAL
::STEP1
cls
net.exe session 1>NUL 2>NUL || (echo Этот сценарий требует права администратора. & pause && exit /b 1)
echo Завершите работу офисных приложений, т.к. далее завершение будет принудительным!
echo.
pause
taskkill /T /F /IM EXCEL.exe
taskkill /T /F /IM WINWORD.exe
taskkill /T /F /IM POWERPNT.exe

::STEP2
::https://support.microsoft.com/en-us/kb/290537
::https://support.microsoft.com/en-us/kb/3025036
::Поиск и удаление файлов *.exd глобально! на системном диске
%systemdrive%
cd \
del /F /Q /S /A:H /A:-H *.exd

::Поиск и удаление файлов *.exd по пути переменных %Temp% и %Tmp% т.к. они могут ссылаться на диск отличный от системного
if exist %Temp% cd /d %Temp%&&del /F /Q /S /A:H /A:-H *.exd
if exist %Tmp% cd /d %Tmp%&&del /F /Q /S /A:H /A:-H *.exd

::Поиск и удаление файлов *.exd в профиле пользователя, на тот случай если профиль пользователя является перемещаемым и расположен на диске отличном от системного
if exist "%APPDATA%\Microsoft\Local" cd /d "%APPDATA%\Microsoft\Local"&&del /F /Q /S /A:H /A:-H *.exd
if exist "%APPDATA%\Microsoft\Forms" cd /d "%APPDATA%\Microsoft\Forms"&&del /F /Q /S /A:H /A:-H *.exd
if exist "%APPDATA%\Roaming\Microsoft\Forms" cd /d "%APPDATA%\Roaming\Microsoft\Forms"&&del /F /Q /S /A:H /A:-H *.exd
if exist "%USERPROFILE%\Local Settings\Temp" cd /d "%USERPROFILE%\Local Settings\Temp"&&del /F /Q /S /A:H /A:-H *.exd

::STEP3
::Перерегистрация библиотеки FM20.DLL
if exist "%windir%\System32\FM20.DLL" "%windir%\System32\regsvr32.exe" /u /s "%windir%\System32\FM20.DLL"
if exist "%windir%\SysWOW64\FM20.DLL" "%windir%\SysWOW64\regsvr32.exe" /u /s "%windir%\SysWOW64\FM20.DLL"

if exist "%windir%\System32\FM20.DLL" "%windir%\System32\regsvr32.exe" /s "%windir%\System32\FM20.DLL"
if exist "%windir%\SysWOW64\FM20.DLL" "%windir%\SysWOW64\regsvr32.exe" /s "%windir%\SysWOW64\FM20.DLL"

::STEP4
::https://msdn.microsoft.com/en-us/library/bb688194(v=vs.85).aspx
::Корректировка параметра Compatibility Flags, который отключает запуск элемента управления ActiveX
::Удаление параметра AlternateCLSID, который может присутствовать и перенаправлять на другой CLSID, а значение параметра Compatibility Flags в этом случае не учитывается

set key-01=HKLM\SOFTWARE\Microsoft\Office\Common\COM Compatibility\{D7053240-CE69-11CD-A777-00DD01143C57}
set key-02=HKLM\SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility\{D7053240-CE69-11CD-A777-00DD01143C57}
set key-03=HKLM\SOFTWARE\Wow6432Node\Microsoft\Office\Common\COM Compatibility\{D7053240-CE69-11CD-A777-00DD01143C57}
set key-04=HKLM\SOFTWARE\Wow6432Node\Microsoft\Internet Explorer\ActiveX Compatibility\{D7053240-CE69-11CD-A777-00DD01143C57}

:reg-query-01
reg query "%key-01%" /s
if %errorlevel%==0 GOTO action-01
GOTO reg-query-02

:action-01
reg add "%key-01%" /v "Compatibility Flags" /t reg_dword /d 8388608 /f
reg delete "%key-01%" /v "AlternateCLSID" /f
GOTO reg-query-02

:reg-query-02
reg query "%key-02%" /s
if %errorlevel%==0 GOTO action-02
GOTO reg-query-03

:action-02
reg add "%key-02%" /v "Compatibility Flags" /t reg_dword /d 8388608 /f
reg delete "%key-02%" /v "AlternateCLSID" /f
GOTO reg-query-03

:reg-query-03
reg query "%key-03%" /s
if %errorlevel%==0  GOTO action-03
GOTO reg-query-04

:action-03
reg add "%key-03%" /v "Compatibility Flags" /t reg_dword /d 8388608 /f
reg delete "%key-03%" /v "AlternateCLSID" /f
GOTO reg-query-04

:reg-query-04
reg query "%key-04%" /s
if %errorlevel%==0  GOTO action-04
GOTO end

:action-04
reg add "%key-04%" /v "Compatibility Flags" /t reg_dword /d 8388608 /f
reg delete "%key-04%" /v "AlternateCLSID" /f
GOTO end

:end
ENDLOCAL
echo.
echo Работа завершена.
echo.
pause
exit /B

HKLM\SOFTWARE\Microsoft\Internet Explorer\ActiveX Compatibility\{8BD21D50-EC42-11CE-9E0D-00AA006002F3}\Compatibility Flags

Type: REG_DWORD, Data: 1024