Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Плотность вещества в зависимости от температуры - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Плотность вещества в зависимости от температуры (Формулы/Formulas)
Плотность вещества в зависимости от температуры
roman1403 Дата: Среда, 20.11.2024, 11:33 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

Добрый день!
Необходима формула для нахождения плотности вещества из таблицы в зависимости от температуры. Температура может быть разной. Например - 14 градусов, т.е. между -10 и -20 градусами в таблице.
К сообщению приложен файл: 3125857.xlsx (8.8 Kb)
 
Ответить
СообщениеДобрый день!
Необходима формула для нахождения плотности вещества из таблицы в зависимости от температуры. Температура может быть разной. Например - 14 градусов, т.е. между -10 и -20 градусами в таблице.
Автор - roman1403
Дата добавления - 20.11.2024 в 11:33
bigor Дата: Среда, 20.11.2024, 11:51 | Сообщение № 2
Группа: Проверенные
Ранг: Старожил
Сообщений: 1267
Репутация: 244 ±
Замечаний: 0% ±

нет
roman1403, а какая плотность при -14 ⁰ ?

p=-0,00001123099709724*t^3+0,000481820536308*t^2-1,15625756614994*t+813,522379236836 , если +/-1 кг/м3 роли не игрет


Сообщение отредактировал bigor - Среда, 20.11.2024, 12:06
 
Ответить
Сообщениеroman1403, а какая плотность при -14 ⁰ ?

p=-0,00001123099709724*t^3+0,000481820536308*t^2-1,15625756614994*t+813,522379236836 , если +/-1 кг/м3 роли не игрет
Автор - bigor
Дата добавления - 20.11.2024 в 11:51
and_evg Дата: Среда, 20.11.2024, 12:01 | Сообщение № 3
Группа: Проверенные
Ранг: Обитатель
Сообщений: 465
Репутация: 79 ±
Замечаний: 0% ±

Excel 2007
Добрый день.
Код
=ВПР(ОКРУГЛ(E4;-1);B4:C24;2;ЛОЖЬ)
К сообщению приложен файл: 0144555.xlsx (8.9 Kb)
 
Ответить
СообщениеДобрый день.
Код
=ВПР(ОКРУГЛ(E4;-1);B4:C24;2;ЛОЖЬ)
Автор - and_evg
Дата добавления - 20.11.2024 в 12:01
roman1403 Дата: Среда, 20.11.2024, 12:51 | Сообщение № 4
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

and_evg, формула не подходит.. хотелось бы чтобы поточнее вычисляла плотность.
 
Ответить
Сообщениеand_evg, формула не подходит.. хотелось бы чтобы поточнее вычисляла плотность.
Автор - roman1403
Дата добавления - 20.11.2024 в 12:51
roman1403 Дата: Среда, 20.11.2024, 13:25 | Сообщение № 5
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

bigor, нужна именно формула ексель, которая бы при указанной температуре вычисляла плотность. Если -15 градусов например, то плотность между 836 и 825 (плотность должна быть равна 830,5)
 
Ответить
Сообщениеbigor, нужна именно формула ексель, которая бы при указанной температуре вычисляла плотность. Если -15 градусов например, то плотность между 836 и 825 (плотность должна быть равна 830,5)
Автор - roman1403
Дата добавления - 20.11.2024 в 13:25
bigor Дата: Среда, 20.11.2024, 13:33 | Сообщение № 6
Группа: Проверенные
Ранг: Старожил
Сообщений: 1267
Репутация: 244 ±
Замечаний: 0% ±

нет
Цитата roman1403, 20.11.2024 в 13:25, в сообщении № 5 ()
Если -15 градусов например, то плотность между 836 и 825 (плотность должна быть равна 830,5)
подставьте в мою формулу вместо t -15 и получите 831, если точность не устраивает, можно взять полином 4 степени


Сообщение отредактировал bigor - Среда, 20.11.2024, 13:35
 
Ответить
Сообщение
Цитата roman1403, 20.11.2024 в 13:25, в сообщении № 5 ()
Если -15 градусов например, то плотность между 836 и 825 (плотность должна быть равна 830,5)
подставьте в мою формулу вместо t -15 и получите 831, если точность не устраивает, можно взять полином 4 степени
Автор - bigor
Дата добавления - 20.11.2024 в 13:33
Nic70y Дата: Среда, 20.11.2024, 14:22 | Сообщение № 7
Группа: Друзья
Ранг: Экселист
Сообщений: 9000
Репутация: 2367 ±
Замечаний: 0% ±

Excel 2010
...я так вижу©
Код
=ЕСЛИОШИБКА(ВПР(E4;B4:C24;2;);ВПР(E4;B4:C24;2)-(ВПР(E4;B4:C24;2)-ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24)+1))/(ИНДЕКС(B4:B24;ПОИСКПОЗ(E4;B4:B24)+1)-ВПР(E4;B4:B24;1))*(E4-ВПР(E4;B4:B24;1)))
К сообщению приложен файл: 47.xlsx (9.1 Kb)

ЮMoney 41001841029809
 
Ответить
Сообщение...я так вижу©
Код
=ЕСЛИОШИБКА(ВПР(E4;B4:C24;2;);ВПР(E4;B4:C24;2)-(ВПР(E4;B4:C24;2)-ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24)+1))/(ИНДЕКС(B4:B24;ПОИСКПОЗ(E4;B4:B24)+1)-ВПР(E4;B4:B24;1))*(E4-ВПР(E4;B4:B24;1)))
Автор - Nic70y
Дата добавления - 20.11.2024 в 14:22
Arti3223 Дата: Среда, 20.11.2024, 15:18 | Сообщение № 8
Группа: Пользователи
Ранг: Новичок
Сообщений: 14
Репутация: 10 ±
Замечаний: 0% ±

2016
Еще один вариант

Код
=ЕСЛИОШИБКА(ВПР(E4;B4:C24;2;);МЕДИАНА(ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24););ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24)+1;)))
 
Ответить
СообщениеЕще один вариант

Код
=ЕСЛИОШИБКА(ВПР(E4;B4:C24;2;);МЕДИАНА(ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24););ИНДЕКС(C4:C24;ПОИСКПОЗ(E4;B4:B24)+1;)))
Автор - Arti3223
Дата добавления - 20.11.2024 в 15:18
Светлый Дата: Среда, 20.11.2024, 15:52 | Сообщение № 9
Группа: Друзья
Ранг: Старожил
Сообщений: 1851
Репутация: 523 ±
Замечаний: 0% ±

Excel 2013, 2016
При линейной интерполяции можно воспользоваться такой формулой:
Код
=(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);))*СУММПРОИЗВ(СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})/СУММПРОИЗВ(СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
или немного упрощённой для начала диапазона:
Код
=(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);))*СУММПРОИЗВ(СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})/10+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
где в ячейке E3 заданная температура.
*Оптимизируем:
Код
=ПРОИЗВЕД(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24););МУМНОЖ(ТРАНСП(СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);;2;2));{-1:1})^{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
**
Код
=ПРОИЗВЕД(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24););МУМНОЖ(ТРАНСП(СМЕЩ(B3:C4;ПОИСКПОЗ(E3;B4:B24);));{-1:1})^{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
К сообщению приложен файл: 3125857_1.xlsx (14.5 Kb)

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Среда, 20.11.2024, 16:08
 
Ответить
СообщениеПри линейной интерполяции можно воспользоваться такой формулой:
Код
=(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);))*СУММПРОИЗВ(СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})/СУММПРОИЗВ(СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
или немного упрощённой для начала диапазона:
Код
=(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);))*СУММПРОИЗВ(СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);;2)*{-1:1})/10+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
где в ячейке E3 заданная температура.
*Оптимизируем:
Код
=ПРОИЗВЕД(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24););МУМНОЖ(ТРАНСП(СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24);;2;2));{-1:1})^{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
**
Код
=ПРОИЗВЕД(E3-СМЕЩ(B3;ПОИСКПОЗ(E3;B4:B24););МУМНОЖ(ТРАНСП(СМЕЩ(B3:C4;ПОИСКПОЗ(E3;B4:B24);));{-1:1})^{-1:1})+СМЕЩ(C3;ПОИСКПОЗ(E3;B4:B24);)
Автор - Светлый
Дата добавления - 20.11.2024 в 15:52
jakim Дата: Среда, 20.11.2024, 15:53 | Сообщение № 10
Группа: Друзья
Ранг: Старожил
Сообщений: 1216
Репутация: 316 ±
Замечаний: 0% ±

Excel 2010
Формула

Код
=FORECAST($F$3,OFFSET($C$3,MATCH($F$3,$B$4:$B$145),,2),OFFSET($B$3,MATCH($F$3,$B$4:$B$145),,2))
К сообщению приложен файл: 4631973.xlsx (9.6 Kb)
 
Ответить
Сообщение
Формула

Код
=FORECAST($F$3,OFFSET($C$3,MATCH($F$3,$B$4:$B$145),,2),OFFSET($B$3,MATCH($F$3,$B$4:$B$145),,2))
Автор - jakim
Дата добавления - 20.11.2024 в 15:53
roman1403 Дата: Среда, 20.11.2024, 16:40 | Сообщение № 11
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

Спасибо всем! Все формулы работают.
 
Ответить
СообщениеСпасибо всем! Все формулы работают.
Автор - roman1403
Дата добавления - 20.11.2024 в 16:40
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Плотность вещества в зависимости от температуры (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!