Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Выбор по таб.№ - категории из крайней заполненной ячейки - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Выбор по таб.№ - категории из крайней заполненной ячейки (Формулы/Formulas)
Выбор по таб.№ - категории из крайней заполненной ячейки
DrMini Дата: Воскресенье, 17.11.2024, 16:01 | Сообщение № 1
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Здравствуйте форумчане и гости форума.
В течении года у работника меняется разряд/профессия.
Как формулой выбрать по табельному номеру наименование профессии, которая была записана самой последней в строке этого табельного номера. Думаю описание не очень. В файле всё понятнее.
В файле показал, как должно получится.
UPD:
посидел подумал - вышла вот такая формула:
Код
=ВПР(A3;F$2:J$5;ВПР(A3;F$2:L$5;7;)+1;)

Вот бы от дополнительного столбца L2:L5 избавиться.
Подскажите пожалуйста. Решение не обязательно должно быть при помощи ВПР.
К сообщению приложен файл: kategorija_razrjad.xlsx (10.1 Kb)


Сообщение отредактировал DrMini - Воскресенье, 17.11.2024, 16:17
 
Ответить
СообщениеЗдравствуйте форумчане и гости форума.
В течении года у работника меняется разряд/профессия.
Как формулой выбрать по табельному номеру наименование профессии, которая была записана самой последней в строке этого табельного номера. Думаю описание не очень. В файле всё понятнее.
В файле показал, как должно получится.
UPD:
посидел подумал - вышла вот такая формула:
Код
=ВПР(A3;F$2:J$5;ВПР(A3;F$2:L$5;7;)+1;)

Вот бы от дополнительного столбца L2:L5 избавиться.
Подскажите пожалуйста. Решение не обязательно должно быть при помощи ВПР.
Автор - DrMini
Дата добавления - 17.11.2024 в 16:01
gling Дата: Воскресенье, 17.11.2024, 16:28 | Сообщение № 2
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2567
Репутация: 709 ±
Замечаний: 0% ±

2010
Здравствуйте.
Попробуйте вариант без доп столбца.
Код
=ИНДЕКС(ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;););ПОИСКПОЗ("яя";ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;);)))

ЯД-41001506838083
 
Ответить
СообщениеЗдравствуйте.
Попробуйте вариант без доп столбца.
Код
=ИНДЕКС(ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;););ПОИСКПОЗ("яя";ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;);)))
Автор - gling
Дата добавления - 17.11.2024 в 16:28
DrMini Дата: Воскресенье, 17.11.2024, 16:35 | Сообщение № 3
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Большое спасибо Владимир, — работает.
 
Ответить
СообщениеБольшое спасибо Владимир, — работает.
Автор - DrMini
Дата добавления - 17.11.2024 в 16:35
Pelena Дата: Воскресенье, 17.11.2024, 16:53 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 19409
Репутация: 4558 ±
Замечаний: ±

Excel 365 & Mac Excel
Ещё вариант
Код
=ПРОСМОТР("яяя";ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;);))

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЕщё вариант
Код
=ПРОСМОТР("яяя";ИНДЕКС($G$2:$J$5;ПОИСКПОЗ(A3;$F$2:$F$5;);))
Автор - Pelena
Дата добавления - 17.11.2024 в 16:53
DrMini Дата: Воскресенье, 17.11.2024, 17:25 | Сообщение № 5
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Большое спасибо Елена, — работает.
 
Ответить
СообщениеБольшое спасибо Елена, — работает.
Автор - DrMini
Дата добавления - 17.11.2024 в 17:25
Egyptian Дата: Воскресенье, 17.11.2024, 23:13 | Сообщение № 6
Группа: Проверенные
Ранг: Ветеран
Сообщений: 527
Репутация: 193 ±
Замечаний: 0% ±

Excel 2013/2016
Еще парочка для коллекции:
Код
=INDEX($G$2:$J$5;MATCH($A3;$F$2:$F$5;);MAX(INDEX((COLUMN($G$2:$J$5)-COLUMN($G$2)+1)*($G$2:$J$5<>"")*($A3=$F$2:$F$5);)))

Массивно:
Код
=INDEX($G$2:$J$5;MATCH(A3;$F$2:$F$5;);COUNTIF(INDEX($G$2:$J$5;MATCH(A3;$F$2:$F$5;););"<>"))
 
Ответить
СообщениеЕще парочка для коллекции:
Код
=INDEX($G$2:$J$5;MATCH($A3;$F$2:$F$5;);MAX(INDEX((COLUMN($G$2:$J$5)-COLUMN($G$2)+1)*($G$2:$J$5<>"")*($A3=$F$2:$F$5);)))

Массивно:
Код
=INDEX($G$2:$J$5;MATCH(A3;$F$2:$F$5;);COUNTIF(INDEX($G$2:$J$5;MATCH(A3;$F$2:$F$5;););"<>"))
Автор - Egyptian
Дата добавления - 17.11.2024 в 23:13
gling Дата: Понедельник, 18.11.2024, 01:16 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2567
Репутация: 709 ±
Замечаний: 0% ±

2010
Цитата Egyptian, 17.11.2024 в 23:13, в сообщении № 6 ()
для коллекции:
Для коллекции придумал попроще своей из сообщения №2.
Код
=ВПР(A3;F:J;СЧЁТЗ(ИНДЕКС(F:J;ПОИСКПОЗ(A3;F:F;);)))
Переделал чуток формулу Михаила из сообщения №1.

ЯД-41001506838083

Сообщение отредактировал gling - Понедельник, 18.11.2024, 01:20
 
Ответить
Сообщение
Цитата Egyptian, 17.11.2024 в 23:13, в сообщении № 6 ()
для коллекции:
Для коллекции придумал попроще своей из сообщения №2.
Код
=ВПР(A3;F:J;СЧЁТЗ(ИНДЕКС(F:J;ПОИСКПОЗ(A3;F:F;);)))
Переделал чуток формулу Михаила из сообщения №1.
Автор - gling
Дата добавления - 18.11.2024 в 01:16
Gustav Дата: Понедельник, 18.11.2024, 02:18 | Сообщение № 8
Группа: Админы
Ранг: Участник клуба
Сообщений: 2810
Репутация: 1184 ±
Замечаний: ±

начинал с Excel 4.0, видел 2.1
Через модернОвые функции для ячейки B3:
[vba]
Код
=REDUCE(; FILTER(G:J; F:F=A3); LAMBDA(a;v;IF(v<>"";v;a)))
[/vba]

МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеЧерез модернОвые функции для ячейки B3:
[vba]
Код
=REDUCE(; FILTER(G:J; F:F=A3); LAMBDA(a;v;IF(v<>"";v;a)))
[/vba]
Автор - Gustav
Дата добавления - 18.11.2024 в 02:18
DrMini Дата: Понедельник, 18.11.2024, 05:22 | Сообщение № 9
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Цитата Egyptian, 17.11.2024 в 23:13, в сообщении № 6 ()
Еще парочка для коллекции

Большое спасибо Георгий, Ваши варианты и с цифрами работают.
 
Ответить
Сообщение
Цитата Egyptian, 17.11.2024 в 23:13, в сообщении № 6 ()
Еще парочка для коллекции

Большое спасибо Георгий, Ваши варианты и с цифрами работают.
Автор - DrMini
Дата добавления - 18.11.2024 в 05:22
DrMini Дата: Понедельник, 18.11.2024, 05:25 | Сообщение № 10
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Цитата Gustav, 18.11.2024 в 02:18, в сообщении № 8 ()
придумал попроще

Спасибо Георгий, попробовал. Работает. С одними цифрами тоже работает.
 
Ответить
Сообщение
Цитата Gustav, 18.11.2024 в 02:18, в сообщении № 8 ()
придумал попроще

Спасибо Георгий, попробовал. Работает. С одними цифрами тоже работает.
Автор - DrMini
Дата добавления - 18.11.2024 в 05:25
DrMini Дата: Понедельник, 18.11.2024, 05:32 | Сообщение № 11
Группа: Друзья
Ранг: Старожил
Сообщений: 1900
Репутация: 276 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Цитата Gustav, 18.11.2024 в 02:18, в сообщении № 8 ()
Через модернОвые функции

Большое спасибо Константин, Да Ваш модернОвый вариант работает.
Вдруг кому пригодится вариант для русскоязычного Excel:
Код
=REDUCE(;ФИЛЬТР(G:J;F:F=A3);LAMBDA(a;v;ЕСЛИ(v<>"";v;a)))
 
Ответить
Сообщение
Цитата Gustav, 18.11.2024 в 02:18, в сообщении № 8 ()
Через модернОвые функции

Большое спасибо Константин, Да Ваш модернОвый вариант работает.
Вдруг кому пригодится вариант для русскоязычного Excel:
Код
=REDUCE(;ФИЛЬТР(G:J;F:F=A3);LAMBDA(a;v;ЕСЛИ(v<>"";v;a)))
Автор - DrMini
Дата добавления - 18.11.2024 в 05:32
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Выбор по таб.№ - категории из крайней заполненной ячейки (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!