Выставление оценок через формулы

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Выставление оценок через формулы (Формулы/Formulas)

Admnis

Дата: Среда, 02.11.2022, 11:31 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 16

Репутация: 0 ±

Замечаний: 20% ±

Excel 2016

Добрый день, форумчане!

Подскажите, Необходимо чтоб в столбце F отображалось "Отл" если в столбцах C,D,E, при наличии одной "Хор"
А если уже две и более "Хор", то отображалось бы "Хор"
Пример прилагаю. Нужно именно чтоб формулой, макросы не работают.
Пробовал сам но не получилось Формулой

Код

=ЕСЛИ(ЕОШИБКА(НАЙТИ("Неуд";C2&D2&E2));ЕСЛИ(ЕОШИБКА(НАЙТИ("Уд";C2&D2&E2));ЕСЛИ(ЕОШИБКА(НАЙТИ("Хор";C2&D2&E2));"Отл";"Хор");"Уд");"Неуд")

Сообщение отредактировал Serge_007 - Среда, 02.11.2022, 11:46

Ответить

Serge_007

Дата: Среда, 02.11.2022, 11:49 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2749 ±

Замечаний: ±

Excel 2016

Цитата Admnis, 02.11.2022 в 11:31, в сообщении № 1 (

)

"Отл" если в столбцах C,D,E, при наличии одной "Хор"

Цитата Admnis, 02.11.2022 в 11:31, в сообщении № 1 (

)

А если уже две и более "Хор", то отображалось бы "Хор"

Вы не ошибаетесь?
За одну "Хор" ставить "Отл", а за две и более "Хор" ставить "Хор"?

Цитата Admnis, 02.11.2022 в 11:31, в сообщении № 1 (

)

Пример прилагаю

Куда прилагаете?

ЮMoney:41001419691823 | WMR:126292472390

Ответить

cmivadwot

Дата: Среда, 02.11.2022, 23:35 | Сообщение № 3

Группа: Проверенные

Ранг: Ветеран

Сообщений: 534

Репутация: 97 ±

Замечаний: 0% ±

365

Admnis, непонятные критерии... а 2 и 3 не может быть?

К сообщению приложен файл: 7096776.xlsx (13.6 Kb)

Ответить

Gustav

Дата: Четверг, 03.11.2022, 02:03 | Сообщение № 4

Группа: Админы

Ранг: Участник клуба

Сообщений: 2797

Репутация: 1161 ±

Замечаний: ±

начинал с Excel 4.0, видел 2.1

Если правильно понял, то как-то так, наверное:

Код

=ЕСЛИ(СЧЁТЕСЛИ(C2:E2;"Неуд");"Неуд";ЕСЛИ(СЧЁТЕСЛИ(C2:E2;"Уд");"Уд";ЕСЛИ(СЧЁТЕСЛИ(C2:E2;"Хор")>1;"Хор";"Отл")))

или вид а-ля Beautifier
[vba]

Код

=ЕСЛИ(
    СЧЁТЕСЛИ(C2:E2;"Неуд");
    "Неуд";
    ЕСЛИ(
        СЧЁТЕСЛИ(C2:E2;"Уд");
        "Уд";
        ЕСЛИ(
            СЧЁТЕСЛИ(C2:E2;"Хор")>1;
            "Хор";
            "Отл"
        )
    )
)

[/vba]
Разумеется, это при условии, что все три ячейки в C2:E2 заполнены оценками (т.е. ячейки не пусты).

[p.s.]А на случай несмежных ячеек можно так:[/p.s.]
[vba]

Код

=ЕСЛИ(
    ЕЧИСЛО(ПОИСК("Неуд";C2&E2&H2));
    "Неуд";
    ЕСЛИ(
        ЕЧИСЛО(ПОИСК("Уд";C2&E2&H2));
        "Уд";
        ЕСЛИ(
            СУММ(C2="Хор";E2="Хор";H2="Хор")>1;
            "Хор";
            "Отл"
        )
    )
)

[/vba]