Подставить значения в ячейку с разделителем из массива. - Мир MS Excel

Регистрация

Напомнить пароль

= Мир MS Excel/Подставить значения в ячейку с разделителем из массива. - Мир MS Excel

Старая форма входа

Страница 1 из 2 1 2 »
Модератор форума: китин, _Boroda_

Подставить значения в ячейку с разделителем из массива. (Формулы/Formulas)

Подставить значения в ячейку с разделителем из массива.

Дата: Понедельник, 25.07.2022, 15:51 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Добрый день камрады,

Есть такая дилемма, есть массив данных, состоящий из столбцов "ID", "Артикул", "Др.Цвета".

Нужно на основании артикулов в столбце "B" как критерия, проанализировать данные в столбце "С" (Др.Цвета) и если там есть одинаковые артикулы, то в столбце "D" "Смена Артикулов Др. Цвета на ID", проставить номера ID через точку с запятой из столбца "А" (ID). То есть по сути, должно выглядить так же как и в столбце "C", только за место Артикулов цвета церез точку с запятой должны стоять ID.

Пока, ну ни как не получается решить данную задачу, хочется её решить именно формулой а не макросом. Прошу Вашей помощи. ^_^

^_^

Файл прилагаю.

К сообщению приложен файл: 0365139.xlsx (22.5 Kb)

Ответить

Дата: Понедельник, 25.07.2022, 16:47 | Сообщение № 2

Группа: Друзья

Ранг: Экселист

Сообщений: 9006

Репутация: 2369 ±

Замечаний: 0% ±

Excel 2010

Цитата 9601216, 25.07.2022 в 15:51, в сообщении № 1 (

)

хочется её решить именно формулой

мне кажется, что это нереально.

К сообщению приложен файл: 52.xlsx (34.6 Kb)

ЮMoney 41001841029809

Ответить

Дата: Понедельник, 25.07.2022, 18:05 | Сообщение № 3

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Добрый день Nic70y,

Эх, печалька, благодарю Вас за предоставленное решение, жаль нельзя это реализовать как хотелось, значит придётся использовать Ваше решение на дополнительной странице..

С Уважением!

Ответить

scriptapplications

Дата: Понедельник, 25.07.2022, 18:40 | Сообщение № 4

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

9601216, для решения этой задачи потребуется версия Excel с функцией ОБЪЕДИНИТЬ (либо бесплатная, мобильная или онлайн, версия либо начиная с Excel 2019)

Формула массива для ячейки D2:

Код

=ОБЪЕДИНИТЬ(";";1;ЕСЛИОШИБКА(ИНДЕКС($A$2:$A$59;ПОИСКПОЗ(СЖПРОБЕЛЫ(ПСТР( C2; НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ(3); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "" )) + 1)))); НАЙТИ( ";"; ";"&C2&"+"; НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ( 3 ); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "")) + 1)))) + 1) - НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ(3); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "")) + 1)))) - 1));$B$2:$B$59;0));""))

Пример решения в прикрепленном файле, запускать надо на версии с функцией ОБЪЕДИНИТЬ

К сообщению приложен файл: 0365139_1.xlsx (28.1 Kb)

Сообщение отредактировал scriptapplications - Понедельник, 25.07.2022, 18:46

Ответить

Дата: Понедельник, 25.07.2022, 20:44 | Сообщение № 5

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Добрый день scriptapplications,

У меня как раз версия 2019, однако мне необходимо чтоб в каждую ячейку через точку с запятой проставлялись значения из столбца "А", если значение артикула в той же строке в столбце "B" совпадает со значениями в столбце "С".

То есть к примеру в D2, должно получится: 87886; 87887; 87888; 87889; 87890; 87891; 87892; 87893.

Ответить

прохожий2019

Дата: Понедельник, 25.07.2022, 20:59 | Сообщение № 6

Группа: Проверенные

Ранг: Старожил

Сообщений: 1298

Репутация: 327 ±

Замечаний: 0% ±

365 Beta Channel

ну если с объединить...

Код

=ОБЪЕДИНИТЬ(";";;MAP(ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(Для_Алексея[@[Др. цвета]];"; ";"</i><i>")&"</i></j>";"//i");LAMBDA(a;ИНДЕКС(Для_Алексея[ID];ПОИСКПОЗ(a;Для_Алексея[Артикул];0)))))

Код

=ОБЪЕДИНИТЬ(";";;MAP(ФИЛЬТР.XML("<j><i>"&ПОДСТАВИТЬ(Для_Алексея[@[Др. цвета]];"; ";"</i><i>")&"</i></j>";"//i");LAMBDA(a;ПРОСМОТРX(a;Для_Алексея[Артикул];Для_Алексея[ID]))))

Код

=ОБЪЕДИНИТЬ(";";;MAP(ТЕКСТРАЗД(Для_Алексея[@[Др. цвета]];"; ");LAMBDA(a;ПРОСМОТРX(a;Для_Алексея[Артикул];Для_Алексея[ID]))))

К сообщению приложен файл: 6852051.xlsx (28.2 Kb)

Ответить

Дата: Понедельник, 25.07.2022, 21:30 | Сообщение № 7

Группа: Проверенные

Ранг: Ветеран

Сообщений: 526

Репутация: 193 ±

Замечаний: 0% ±

Excel 2013/2016

Может так?

Код

=TEXTJOIN("; ";1;IF(Для_Алексея[Артикул]=TRANSPOSE(FILTERXML("< t >< s >"&SUBSTITUTE(SUBSTITUTE(C2;";";);" ";"< / s>< s >")&"< /s >< /t >";"//s"));Для_Алексея[ID];""))

P.S. Формулу копируйте с прикрепленного файла, поскольку теги искажают ее.

К сообщению приложен файл: 0365139.xlsb (28.3 Kb)

Сообщение отредактировал Egyptian - Понедельник, 25.07.2022, 21:32

Ответить

scriptapplications

Дата: Понедельник, 25.07.2022, 21:48 | Сообщение № 8

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

9601216, Вы правы, в формулу закралась опечатка и последний ID не входил в результат.
Исправленная версия формулы для ячейки D2:

Код

=ОБЪЕДИНИТЬ(";";1;ЕСЛИОШИБКА(ИНДЕКС($A$2:$A$59;ПОИСКПОЗ(СЖПРОБЕЛЫ(ПСТР( C2; НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ(3); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "" )) + 1)))); НАЙТИ( ";"; ";"&C2&";"; НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ( 3 ); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "")) + 1)))) + 1) - НАЙТИ( СИМВОЛ( 3 ); ПОДСТАВИТЬ( ";"&C2; ";"; СИМВОЛ(3); СТРОКА( ДВССЫЛ( "1:"&ДЛСТР( C2 ) - ДЛСТР( ПОДСТАВИТЬ( C2; ";"; "")) + 1)))) - 1));$B$2:$B$59;0));""))

Содержимое ячейки D2 во вложенном файле полностью соответствует значению в приведённом примере.

К сообщению приложен файл: 0365139_2.xlsx (26.7 Kb)

Сообщение отредактировал scriptapplications - Понедельник, 25.07.2022, 21:54

Ответить

Дата: Вторник, 26.07.2022, 10:55 | Сообщение № 9

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

scriptapplications приветствую,

Странно, у меня второй файл открывается вот так... см.вл.фл.

К сообщению приложен файл: 1502239.jpg (89.0 Kb)

Ответить

Дата: Вторник, 26.07.2022, 11:07 | Сообщение № 10

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Добрый день Egyptian,

Ваше решение идеально подходит, подскажите, где можно почитать о таком построении функции, изучить так сказать..?

И благодарю за решение!!!

Ответить

scriptapplications

Дата: Вторник, 26.07.2022, 12:55 | Сообщение № 11

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

9601216, у Вас формула не работает как формула массива, попробуйте в ячейке D2 ввести формулу нажатием CTRL+Shift+Enter, у меня на мобильнике всё работает правильно

К сообщению приложен файл: 2721499.png (197.0 Kb)

Сообщение отредактировал scriptapplications - Вторник, 26.07.2022, 12:59

Ответить

Дата: Вторник, 26.07.2022, 13:19 | Сообщение № 12

Группа: Проверенные

Ранг: Ветеран

Сообщений: 526

Репутация: 193 ±

Замечаний: 0% ±

Excel 2013/2016

9601216, Почитайте тут. Правда на буржуйском, но зато есть конкретные примеры.

Ответить

Дата: Вторник, 26.07.2022, 15:16 | Сообщение № 13

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Egyptian Благодарю!

Ответить

Дата: Вторник, 26.07.2022, 17:10 | Сообщение № 14

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Очень странная история у меня, когда Ваш файл открываю в первый раз, то он у меня открывается и я вижу что формула работает, то есть там есть данные через разделитель как надо, но как только я нажимаю разрешить редактирование, то формула перестаёт работать и у меня данные не сцепленные вместе через разделитель, а только один номер ID.. Я в предыдущий раз тоже подумал что дело наверно в том что я нажал на ячейку и может быть потом щёлкнул enter, но навёл на неё мышь, нет массив, попробовал ещё раз cntrl + shift + enter, не помогло..

Даже не предполагаю из-за чего это может быть.. ((

К сообщению приложен файл: 9426137.jpg (68.8 Kb)

Ответить

scriptapplications

Дата: Вторник, 26.07.2022, 18:01 | Сообщение № 15

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

9601216, возможно влияет режим умной таблицы, или несоответствие версий Excel.
Попробуйте вырезать формулу в режиме редактирования и поставить в ячейку F2, завершив редактирование нажатием комбинации Ctrl+Shift+ENTER.
Или скопируйте формулу (в режиме редактирования) в свой файл в пустую ячейку D2 и нажмите Ctrl+Shift+Enter.

Сообщение отредактировал scriptapplications - Вторник, 26.07.2022, 18:17

Ответить

Дата: Понедельник, 01.08.2022, 16:35 | Сообщение № 16

Группа: Пользователи

Ранг: Прохожий

Сообщений: 8

Репутация: 0 ±

Замечаний: 0% ±

Благодарю за совет, однако не помогло, так же включил проверку на совместимость, но у меня 2021 Excel, должен быть совместим, но нет. Так же копировал всё на другой лист, без умной таблицы, просто как данные, но всё ровно не помогло.. Очень странно..((

Ответить

scriptapplications

Дата: Понедельник, 01.08.2022, 18:43 | Сообщение № 17

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

9601216, у меня под рукой нет такой версии, на которой не работает, но может быть у Вас тестовая версия Excel или может это баг, который исправится после обновления?

Ответить

Дата: Понедельник, 01.08.2022, 19:41 | Сообщение № 18

Группа: Проверенные

Ранг: Ветеран

Сообщений: 526

Репутация: 193 ±

Замечаний: 0% ±

Excel 2013/2016

scriptapplications, А у вас какая версия? У меня тоже не работает: пробовал на компе с Excel 2019, ни на 2013 или 2016 с UDF эмулятором.

Ответить

Дата: Понедельник, 01.08.2022, 20:38 | Сообщение № 19

Группа: Админы

Ранг: Местный житель

Сообщений: 19405

Репутация: 4555 ±

Замечаний: ±

Excel 365 & Mac Excel

Ещё вариант для новых версий

Код

=ОБЪЕДИНИТЬ(";";1;ИНДЕКС([ID];ПОИСКПОЗ(ТЕКСТРАЗД([@[Др. цвета]];"; ");[Артикул];0);0))

К сообщению приложен файл: 1034711.xlsx (28.1 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

scriptapplications

Дата: Вторник, 02.08.2022, 13:26 | Сообщение № 20

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

Egyptian, у меня мобильный бесплатный Excel под андроид (написано версия 1.0.1... )

Ответить

Подставить значения в ячейку с разделителем из массива. (Формулы/Formulas)

Страница 1 из 2
1
2
»

© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!