Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Подтянуть значение из другой таблицы по 2м соответствиям - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подтянуть значение из другой таблицы по 2м соответствиям (Формулы/Formulas)
Подтянуть значение из другой таблицы по 2м соответствиям
TanyaKatana Дата: Вторник, 05.07.2022, 12:04 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 18
Репутация: 0 ±
Замечаний: 20% ±

Добрый день.

как подтянуть значение столбца Количество из табл 1 по соответствию столбцов Товар и Дата.
Разве не должна работать
Код
{=ЕСЛИ(И(B18=B$3:B$5;C18=C$3:C$5);D$3:D$5)}
?
К сообщению приложен файл: _3.xlsx (9.5 Kb)
 
Ответить
СообщениеДобрый день.

как подтянуть значение столбца Количество из табл 1 по соответствию столбцов Товар и Дата.
Разве не должна работать
Код
{=ЕСЛИ(И(B18=B$3:B$5;C18=C$3:C$5);D$3:D$5)}
?
Автор - TanyaKatana
Дата добавления - 05.07.2022 в 12:04
Egyptian Дата: Вторник, 05.07.2022, 12:12 | Сообщение № 2
Группа: Проверенные
Ранг: Ветеран
Сообщений: 526
Репутация: 193 ±
Замечаний: 0% ±

Excel 2013/2016
Код
=SUMIFS($D$3:$D$5;$B$3:$B$5;H3;$C$3:$C$5;I3)

Только во второй таблице мясцо попадается с пробелами.
 
Ответить
Сообщение
Код
=SUMIFS($D$3:$D$5;$B$3:$B$5;H3;$C$3:$C$5;I3)

Только во второй таблице мясцо попадается с пробелами.
Автор - Egyptian
Дата добавления - 05.07.2022 в 12:12
TanyaKatana Дата: Вторник, 05.07.2022, 12:36 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 18
Репутация: 0 ±
Замечаний: 20% ±

Цитата Egyptian, 05.07.2022 в 12:12, в сообщении № 2 ()
=СУММЕСЛИМН($D$3:$D$5;$B$3:$B$5;H3;$C$3:$C$5;I3)

Спасибо. А если в столбце Количество будут текстовые значения, как я понимаю, работать не будет?

уже понял что не работает. А как тогда можно подтянуть значение, если оно текстовое? по условию, что два значение в двух ячейках строки таблицы соответствуют таким же значениям другой таблицы?


Сообщение отредактировал TanyaKatana - Вторник, 05.07.2022, 13:53
 
Ответить
Сообщение
Цитата Egyptian, 05.07.2022 в 12:12, в сообщении № 2 ()
=СУММЕСЛИМН($D$3:$D$5;$B$3:$B$5;H3;$C$3:$C$5;I3)

Спасибо. А если в столбце Количество будут текстовые значения, как я понимаю, работать не будет?

уже понял что не работает. А как тогда можно подтянуть значение, если оно текстовое? по условию, что два значение в двух ячейках строки таблицы соответствуют таким же значениям другой таблицы?
Автор - TanyaKatana
Дата добавления - 05.07.2022 в 12:36
Egyptian Дата: Вторник, 05.07.2022, 14:59 | Сообщение № 4
Группа: Проверенные
Ранг: Ветеран
Сообщений: 526
Репутация: 193 ±
Замечаний: 0% ±

Excel 2013/2016
Можно такой формулой
Код
=SUMPRODUCT($D$3:$D$5*($B$3:$B$5=H3)*($C$3:$C$5=I3))
К сообщению приложен файл: 3620647.xlsx (9.8 Kb)
 
Ответить
СообщениеМожно такой формулой
Код
=SUMPRODUCT($D$3:$D$5*($B$3:$B$5=H3)*($C$3:$C$5=I3))
Автор - Egyptian
Дата добавления - 05.07.2022 в 14:59
TanyaKatana Дата: Вторник, 05.07.2022, 15:09 | Сообщение № 5
Группа: Пользователи
Ранг: Новичок
Сообщений: 18
Репутация: 0 ±
Замечаний: 20% ±

Цитата Egyptian, 05.07.2022 в 14:59, в сообщении № 4 ()
Можно такой формулой

Да, с цифрами оно работает. Но если заменить значение цифры на текст, уже работать не будет
К сообщению приложен файл: 4195473.xlsx (10.0 Kb)
 
Ответить
Сообщение
Цитата Egyptian, 05.07.2022 в 14:59, в сообщении № 4 ()
Можно такой формулой

Да, с цифрами оно работает. Но если заменить значение цифры на текст, уже работать не будет
Автор - TanyaKatana
Дата добавления - 05.07.2022 в 15:09
scriptapplications Дата: Вторник, 05.07.2022, 16:23 | Сообщение № 6
Группа: Проверенные
Ранг: Участник
Сообщений: 68
Репутация: 12 ±
Замечаний: 0% ±

TanyaKatana, воспользуйтесь формулой массива (вводится через CTRL+SHIFT+ENTER)
Код
=СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5)

будет работать и с текстовыми значениями количества и с пробелами, но на пустых ячейках будет 0
если нужно чтобы не было нулей в пустых ячейках

Код
=ЕСЛИ( СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5)<>0;СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5);"")
К сообщению приложен файл: _3_1.xlsx (10.6 Kb)


Сообщение отредактировал scriptapplications - Вторник, 05.07.2022, 16:28
 
Ответить
СообщениеTanyaKatana, воспользуйтесь формулой массива (вводится через CTRL+SHIFT+ENTER)
Код
=СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5)

будет работать и с текстовыми значениями количества и с пробелами, но на пустых ячейках будет 0
если нужно чтобы не было нулей в пустых ячейках

Код
=ЕСЛИ( СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5)<>0;СУММ((--(СЖПРОБЕЛЫ(H3)=СЖПРОБЕЛЫ(B$3:B$5)))*(--(СЖПРОБЕЛЫ(I3)=СЖПРОБЕЛЫ(C$3:C$5)))*$D$3:$D$5);"")
Автор - scriptapplications
Дата добавления - 05.07.2022 в 16:23
Egyptian Дата: Вторник, 05.07.2022, 19:38 | Сообщение № 7
Группа: Проверенные
Ранг: Ветеран
Сообщений: 526
Репутация: 193 ±
Замечаний: 0% ±

Excel 2013/2016
Цитата TanyaKatana, 05.07.2022 в 15:09, в сообщении № 5 ()
Но если заменить значение цифры на текст, уже работать не будет

Наверное потому, что она для этого не предназначена. Изначально приложили бы нормальный пример,не было бы столько лишней писанины.
Код
=IFNA(INDEX($D$3:$D$5;MATCH(1;INDEX((TRIM($B$3:$B$5)=H3)*($C$3:$C$5=I3););));"")
К сообщению приложен файл: 4537930.xlsx (10.1 Kb)
 
Ответить
Сообщение
Цитата TanyaKatana, 05.07.2022 в 15:09, в сообщении № 5 ()
Но если заменить значение цифры на текст, уже работать не будет

Наверное потому, что она для этого не предназначена. Изначально приложили бы нормальный пример,не было бы столько лишней писанины.
Код
=IFNA(INDEX($D$3:$D$5;MATCH(1;INDEX((TRIM($B$3:$B$5)=H3)*($C$3:$C$5=I3););));"")
Автор - Egyptian
Дата добавления - 05.07.2022 в 19:38
_Boroda_ Дата: Среда, 06.07.2022, 12:53 | Сообщение № 8
Группа: Админы
Ранг: Местный житель
Сообщений: 16718
Репутация: 6505 ±
Замечаний: ±

2003; 2007; 2010; 2013 RUS
Еще вариант
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(C$3:C$5=I3)/ПОИСК(H3;B$3:B$5);D$3:D$5);"")

Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/ПОИСК(I3&H3;C$3:C$5&B$3:B$5);D$3:D$5);"")
К сообщению приложен файл: 4195473_1.xlsx (10.3 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЕще вариант
Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/(C$3:C$5=I3)/ПОИСК(H3;B$3:B$5);D$3:D$5);"")

Код
=ЕСЛИОШИБКА(ПРОСМОТР(;-1/ПОИСК(I3&H3;C$3:C$5&B$3:B$5);D$3:D$5);"")
Автор - _Boroda_
Дата добавления - 06.07.2022 в 12:53
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подтянуть значение из другой таблицы по 2м соответствиям (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!