Вытащить в другой столбец дату рождения из ИИН

Старая форма входа

Страница 1 из 2 1 2 »
Модератор форума: китин, _Boroda_

Вытащить в другой столбец дату рождения из ИИН (Формулы/Formulas)

Muhan

Дата: Воскресенье, 04.02.2018, 18:30 | Сообщение № 1

Группа: Проверенные

Ранг: Участник

Сообщений: 65

Репутация: 0 ±

Замечаний: 20% ±

Уважаемые знатоки, подскажите пожалуйста, как формулой извлечь дату рождения из ИИН

К сообщению приложен файл: __2000-1991.xls (55.5 Kb)

Ответить

bmv98rus

Дата: Воскресенье, 04.02.2018, 18:37 | Сообщение № 2

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=DATE(IF((--MID(D3;7;1))>4;2000;1900)+LEFT(D3;2);MID(D3;3;2);MID(D3;5;2))

На ближайшие 82 года :-) без расчета на рожденных в 19м веке

Если ничего не поменяют, то более универсально, хотя для 19го века не сработает, нижняя граница 1900 год. Тяжко аксакалам в excel.

Код

=DATE((17+INT((MID(D3;7;1))/2))%+LEFT(D3;2);MID(D3;3;2);MID(D3;5;2))

Не дальновидно разработано. осталось 4 цифры незанятых или только до 23го века или ... :-)

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Воскресенье, 04.02.2018, 20:47

Ответить

Pelena

Дата: Воскресенье, 04.02.2018, 20:37 | Сообщение № 3

Группа: Админы

Ранг: Местный житель

Сообщений: 19401

Репутация: 4549 ±

Замечаний: ±

Excel 365 & Mac Excel

Вариант

Код

=--(ПСТР(D4;5;2)&"-"&ПСТР(D4;3;2)&"-"&ПСТР(D4;1;2))

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

bmv98rus

Дата: Воскресенье, 04.02.2018, 20:46 | Сообщение № 4

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

Pelena, вариант не учитывает, что в 7 символе век зашит , то есть 1701011 это 01.01.1817 а 2001015 уже 01.01.2017

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Воскресенье, 04.02.2018, 21:36

Ответить

Pelena

Дата: Воскресенье, 04.02.2018, 21:11 | Сообщение № 5

Группа: Админы

Ранг: Местный житель

Сообщений: 19401

Репутация: 4549 ±

Замечаний: ±

Excel 365 & Mac Excel

[offtop]И почему это я никогда не пишу в отношении других отвечающих "плохой вариант", а просто предлагаю альтернативу? Надо перенять опыт [/offtop]

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

bmv98rus

Дата: Воскресенье, 04.02.2018, 21:35 | Сообщение № 6

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

[offtop]Pelena, Без обид, исправил, имел в виду не способ, а не полноту возможных вариантов.[/offtop]

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Воскресенье, 04.02.2018, 21:41

Ответить

Pelena

Дата: Воскресенье, 04.02.2018, 22:33 | Сообщение № 7

Группа: Админы

Ранг: Местный житель

Сообщений: 19401

Репутация: 4549 ±

Замечаний: ±

Excel 365 & Mac Excel

При чём здесь обиды? Я вообще ни на кого никогда не обижаюсь, я делаю выводы

А по поводу формулы, так файл называется 2000-1991, под этот период моя формула подходит

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

bmv98rus

Дата: Воскресенье, 04.02.2018, 22:55 | Сообщение № 8

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

Pelena, Ну если посомтреть на 25ю строку, то 2000-1991 не соответвуют году 90 ;-)
А вот если взглянуть на 21ю и 44ю, то наши формулы дают сбой, там похоже первый ноль пропал. Получается так тогда

Код

=DATE((17+INT((MID(RIGHT("000"&D14;12);7;1))/2))%+LEFT(RIGHT("000"&D14;12);2);MID(RIGHT("000"&D14;12);3;2);MID(RIGHT("000"&D14;12);5;2))

UPD Спасибо Gling, я до 2х нулей считал, он дальше пошел :-)

[p.s.]Вот не напиши я тогда, что формула плоха, вы б не отметили, я б не полез смотреть, и не нашел ошибку. Есть польза :-)[/p.s.]

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Воскресенье, 04.02.2018, 23:54

Ответить

gling

Дата: Воскресенье, 04.02.2018, 23:46 | Сообщение № 9

Группа: Друзья

Ранг: Участник клуба

Сообщений: 2558

Репутация: 696 ±

Замечаний: 0% ±

2010

С отсутствием нуля в начале, можно что то придумать, типа так

Код

=--(ПСТР(ЕСЛИ(ДЛСТР(D3)=12;"";0)&D3;5;2)&"-"&ПСТР(ЕСЛИ(ДЛСТР(D3)=12;"";0)&D3;3;2)&"-"&ПСТР(ЕСЛИ(ДЛСТР(D3)=12;"";0)&D3;1;2))

или так

Код

=--(ПСТР(ТЕКСТ(D3;"000000000000");5;2)&"-"&ПСТР(ТЕКСТ(D3;"000000000000");3;2)&"-"&ПСТР(ТЕКСТ(D3;"000000000000");1;2))

на базе "плохого варианта" формулы. Второй вариант лучше, так как формирует дату и при отсутствии 3 нулей в начале.

ЯД-41001506838083

Ответить

bmv98rus

Дата: Понедельник, 05.02.2018, 00:00 | Сообщение № 10

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

gling, да можно и так, разве что заменить 000000000 можно

Код

=--(MID(TEXT(D3;REPT(0;12));5;2)&"-"&MID(TEXT(D3;REPT(0;12));3;2)&"-"&MID(TEXT(D3;REPT(0;12));1;2))

тогда моя формула проибразится в

Код

=DATE((17+INT((MID(TEXT(D3;REPT(0;12));7;1))/2))%+LEFT(TEXT(D3;REPT(0;12));2);MID(TEXT(D3;REPT(0;12));3;2);MID(TEXT(D3;REPT(0;12));5;2))

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Понедельник, 05.02.2018, 00:56

Ответить

Muhan

Дата: Понедельник, 05.02.2018, 05:00 | Сообщение № 11

Группа: Проверенные

Ранг: Участник

Сообщений: 65

Репутация: 0 ±

Замечаний: 20% ±

Спасибо уважаемые знатоки! Вы мне очень помогли. спасибо!

Ответить

AlexM

Дата: Понедельник, 05.02.2018, 08:18 | Сообщение № 12

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4517

Репутация: 1129 ±

Замечаний: 0% ±

Excel 2003

[offtop]А где такой алгоритм ИНН используется?

Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.

Ответить

Hugo

Дата: Понедельник, 05.02.2018, 09:45 | Сообщение № 13

Группа: Друзья

Ранг: Участник клуба

Сообщений: 3689

Репутация: 790 ±

Замечаний: 0% ±

365

[offtop]У нас решили что вписывать в наш "ИНН" дату рождения недемократично, и предоставляют возможность эту дату вообще не показывать. И заменять уже присвоенные ID на "демократичные".

webmoney: E265281470651 Z422237915069
USDT TRC20: TN8XeEF17o5KPBD9pNwYzNyruycuAc2mVD

Ответить

bmv98rus

Дата: Понедельник, 05.02.2018, 11:20 | Сообщение № 14

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

Цитата AlexM, 05.02.2018 в 08:18, в сообщении № 12 ()

Оффтоп:
А где такой алгоритм ИНН используется

Это именно ИИН, Казахстан Индивидуальный идентификационный номер, а не Индивидуальный номер налогоплатильщика.

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Понедельник, 05.02.2018, 11:22

Ответить

AlexM

Дата: Понедельник, 05.02.2018, 13:21 | Сообщение № 15

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4517

Репутация: 1129 ±

Замечаний: 0% ±

Excel 2003

вариант

Код

=--(ОТБР((ПСТР(ТЕКСТ(D3;ПОВТОР(0;12));7;1)+35)/2)&ТЕКСТ(ЛЕВБ(ТЕКСТ(D3;ПОВТОР(0;12));6);"00\/00\/00"))

или

Код

=--ТЕКСТ(ЛЕВБ(ТЕКСТ(D3;ПОВТОР(0;12));6);ОТБР((ПСТР(ТЕКСТ(D3;ПОВТОР(0;12));7;1)+35)/2)&"00\/00\/00")

или

Код

=--ТЕКСТ(ЛЕВБ(ТЕКСТ(D3;ПОВТОР(0;12));6);ОТБР((ЛЕВБ(ПРАВБ(D3;6))+35)/2)&"00\/00\/00")

Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.

Сообщение отредактировал AlexM - Понедельник, 05.02.2018, 13:33

Ответить

bmv98rus

Дата: Понедельник, 05.02.2018, 17:08 | Сообщение № 16

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

AlexM, Любите Вы запутать своим оригинальным решением :-) в последней формуле сперва не понял почему 6? а не 7 :-) потом пригляделся. hands

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

AlexM

Дата: Понедельник, 05.02.2018, 17:13 | Сообщение № 17

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4517

Репутация: 1129 ±

Замечаний: 0% ±

Excel 2003

bmv98rus, выходит слово запутать нужно поместить в кавычки.

Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.

Ответить

Nic70y

Дата: Понедельник, 05.02.2018, 17:16 | Сообщение № 18

Группа: Друзья

Ранг: Экселист

Сообщений: 8999

Репутация: 2366 ±

Замечаний: 0% ±

Excel 2010

del

ЮMoney 41001841029809

Сообщение отредактировал Nic70y - Понедельник, 05.02.2018, 17:18

Ответить

AlexM

Дата: Понедельник, 05.02.2018, 17:20 | Сообщение № 19

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4517

Репутация: 1129 ±

Замечаний: 0% ±

Excel 2003

Nic70y, меня смутило, но мне в сообщении №14 об ИИН разъяснили.

Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.

Ответить

bmv98rus

Дата: Понедельник, 05.02.2018, 18:02 | Сообщение № 20

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4113

Репутация: 769 ±

Замечаний: 0% ±

Excel 2013/2016

[offtop]

Цитата AlexM, 05.02.2018 в 17:13, в сообщении № 17 ()

запутать нужно поместить в кавычки.

это заменяет смайл следуемый далее. На самом деле, реально порой нелинейность решений поразительна. Вроде и сам знаю что мыслить нужно именно по Excelевски, но все перевертывает, когда получается, что число переводим в число используя форматирование текста и умение excel менять формат данных :-), а конструкция 00\/00\/00 завораживает :-).[/offtop]

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Вытащить в другой столбец дату рождения из ИИН (Формулы/Formulas)

Страница 1 из 2
1
2
»