Функция срзнач без учета ошибок #н/д и дел/0

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Функция срзнач без учета ошибок #н/д и дел/0 (Формулы/Formulas)

alisa111111

Дата: Понедельник, 04.04.2016, 13:54 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 2

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Нужно посчитать сред. значение по строке. Проблема в том, что некоторые ячейки содержать ошибки. Нужно, чтобы среднее значение считалось без их учета.
Не понимаю как указать это условие.
Прописала в таком виде - =СРЗНАЧ(СРЗНАЧЕСЛИ(C3:I3;">0");СРЗНАЧЕСЛИ(C3:I3;"<0"))
Но где-то считает, а где то нет

К сообщению приложен файл: 1698700.xlsx (19.1 Kb)

Ответить

Gustav

Дата: Понедельник, 04.04.2016, 14:04 | Сообщение № 2

Группа: Админы

Ранг: Участник клуба

Сообщений: 2793

Репутация: 1160 ±

Замечаний: ±

начинал с Excel 4.0, видел 2.1

Формула массива (Ctrl+Shift+Enter)

Код

=СРЗНАЧ(ЕСЛИОШИБКА(C2:I2; ""))

До 2007 года (тоже формула массива):

Код

=СРЗНАЧ(ЕСЛИ(ЕОШИБКА(C2:I2); "";C2:I2))

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Понедельник, 04.04.2016, 14:06

Ответить

_Boroda_

Дата: Понедельник, 04.04.2016, 14:05 | Сообщение № 3

Группа: Админы

Ранг: Местный житель

Сообщений: 16713

Репутация: 6503 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Так нужно?

Код

=СРЗНАЧ(ЕСЛИОШИБКА(C2:I2;""))

Формула массива, вводится одновременным нажатием Контрл Шифт Ентер
А если по феншую делать, то нужно поправить те формулы, которые у Вас в столбцах С:I, чтобы они давали не ошибку, а пустое значение "". Тогда можно будет нормально считать.
Типа вот так

Код

=ЕСЛИОШИБКА(формула;"")

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Nic70y

Дата: Понедельник, 04.04.2016, 14:05 | Сообщение № 4

Группа: Друзья

Ранг: Экселист

Сообщений: 8999

Репутация: 2367 ±

Замечаний: 0% ±

Excel 2010

формула массиваКод
=СРЗНАЧ(ЕСЛИ(ЕЧИСЛО(C2:I2);C2:I2))

Код

=ЕСЛИОШИБКА(СРЗНАЧ(ЕСЛИ(ЕЧИСЛО(C2:I2);C2:I2));"")

обратите внимание на B10

Цитата alisa111111, 04.04.2016 в 13:54, в сообщении № 1

Прописала в таком виде

так вам среднее надо или среднее средних?

еще варианты, немассивной
Код
=СУММЕСЛИ(C2:I2;">-9E+307")/СЧЁТЕСЛИ(C2:I2;">-9E+307")
Код
=СРЗНАЧЕСЛИ(C2:I2;">-9E+307")

Код

=ЕСЛИОШИБКА(СУММЕСЛИ(C2:I2;">-9E+307")/СЧЁТЕСЛИ(C2:I2;">-9E+307");"")

Код

=ЕСЛИОШИБКА(СРЗНАЧЕСЛИ(C2:I2;">-9E+307");"")