добавить пробелы в слитный текст ФИО

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

добавить пробелы в слитный текст ФИО (Формулы/Formulas)

mm999

Дата: Четверг, 23.04.2015, 14:22 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 2

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Добрый день!
Подскажите, пожалуйста, как поставить пробелы в слитный текст, содержащий ФИО , например - "ИвановПетрСергеевич", чтобы получилось "Иванов Петр Сергеевич".
Все слова начинаются с заглавных букв.

К сообщению приложен файл: 7905404.xlsx (9.9 Kb)

Сообщение отредактировал mm999 - Четверг, 23.04.2015, 14:40

Ответить

Pelena

Дата: Четверг, 23.04.2015, 15:02 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 19345

Репутация: 4524 ±

Замечаний: ±

Excel 365 & Mac Excel

Здравствуйте.
Как вариант, формула массива

Код

=ЗАМЕНИТЬ(ЗАМЕНИТЬ(A2;НАИМЕНЬШИЙ(ЕСЛИ(СОВПАД(ПСТР(A2;СТРОКА($2:$99);1);ПСТР(ПРОПИСН(A2);СТРОКА($2:$99);1))*СТРОКА($2:$99)>0;СТРОКА($2:$99));2);;" ");МИН(ЕСЛИ(СОВПАД(ПСТР(A2;СТРОКА($2:$99);1);ПСТР(ПРОПИСН(A2);СТРОКА($2:$99);1))*СТРОКА($2:$99)>0;СТРОКА($2:$99)));;" ")

К сообщению приложен файл: 7170427.xlsx (11.2 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

_Boroda_

Дата: Четверг, 23.04.2015, 15:11 | Сообщение № 3

Группа: Админы

Ранг: Местный житель

Сообщений: 16675

Репутация: 6481 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Пока такой вариант

Код

=ЗАМЕНИТЬ(ЗАМЕНИТЬ(A2;МАКС(ЕСЛИ(СОВПАД(ПСТР(A2;СТРОКА($1:$99);1);ПСТР(ПРОПНАЧ(A2);СТРОКА($1:$99);1));"";СТРОКА($1:$99)));;" ");МИН(ЕСЛИ(СОВПАД(ПСТР(A2;СТРОКА($1:$99);1);ПСТР(ПРОПНАЧ(A2);СТРОКА($1:$99);1));"";СТРОКА($1:$99)));;" ")

еще

Код

=ЗАМЕНИТЬ(ЗАМЕНИТЬ(A2;МАКС(ЕСЛИОШИБКА(НАЙТИ(СИМВОЛ(СТРОКА($192:$223));ПСТР(A2;2;99))+1;""));;" ");МИН(ЕСЛИОШИБКА(НАЙТИ(СИМВОЛ(СТРОКА($192:$223));ПСТР(A2;2;99))+1;""));;" ")

Не, здесь две одинаковые буквы не меняет

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

AlexM

Дата: Четверг, 23.04.2015, 15:50 | Сообщение № 4

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4517

Репутация: 1129 ±

Замечаний: 0% ±

Excel 2003

Еще вариант

Код

=ЗАМЕНИТЬ(ЗАМЕНИТЬ(A2;НАИМЕНЬШИЙ(ЕСЛИ(КОДСИМВ(ПСТР(A2;СТРОКА($2:$99);1)&"я")<=223;СТРОКА($2:$99));1);;" ");НАИМЕНЬШИЙ(ЕСЛИ(КОДСИМВ(ПСТР(A2;СТРОКА($2:$99);1)&"я")<=223;СТРОКА($2:$99));2)+1;;" ")

чуть короче

Код

=ЗАМЕНИТЬ(ЗАМЕНИТЬ(A2;МИН(ЕСЛИ(КОДСИМВ(ПСТР(A2;СТРОКА($2:$99);1)&"я")<224;СТРОКА($2:$99)));;" ");МАКС((КОДСИМВ(ПСТР(A2;СТРОКА($2:$99);1)&"я")<224)*СТРОКА($2:$99))+1;;" ")

Все формулы массивные.