Сокращение формулы подстановки значений

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Сокращение формулы подстановки значений (Формулы/Formulas)

ArkaIIIa

Дата: Вторник, 23.09.2014, 10:50 | Сообщение № 1

Группа: Проверенные

Ранг: Ветеран

Сообщений: 894

Репутация: 115 ±

Замечаний: 0% ±

2010

Добрый день, уважаемые господа!

Помогите, пожалуйста, сократить формулу:

Код

=ЕСЛИ(СЧЁТЕСЛИ($F$2:$F$4;A2)>0;$F$1;ЕСЛИ(СЧЁТЕСЛИ($G$2:$G$4;A2)>0;$G$1;ЕСЛИ(СЧЁТЕСЛИ($H$2:$H$4;A2)>0;$H$1;"")))

Особенно интересует вариант с использованием {} - если это возможно.

П.С. Интересует вариант, который требовал бы минимум ресурсов при перерасчете нескольких десятков тысяч строк.
П.П.С. Версия Excel - 2010.

Спасибо.

К сообщению приложен файл: 121212.xls (25.0 Kb)

Сообщение отредактировал ArkaIIIa - Вторник, 23.09.2014, 10:52

Ответить

_Boroda_

Дата: Вторник, 23.09.2014, 10:59 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 16691

Репутация: 6491 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Так нужно?

Код

=СУММПРОИЗВ(F$1:H$1*ЕЧИСЛО(ПОИСК(A2;F$2:H$4)))

Цитата ArkaIIIa, 23.09.2014 в 10:50, в сообщении № 1

Особенно интересует вариант с использованием {}

Код

=СУММ(F$1:H$1*ЕЧИСЛО(ПОИСК(A2;F$2:H$4)))

Добавлено.

Цитата ArkaIIIa, 23.09.2014 в 11:02, в сообщении № 4

думаю, что формула, которую предложил Александр будет завешивать процесс значительно меньше, чем моя

А с точки зрения скорости каскад из ЕСЛИ предпочтительней, конечно.
Да, и конструкция ЕЧИСЛО(ПОИСК - это не обязательно. Нужно только для случаев, когда фамилии в таблице не совсем совпадают с фамилиями в столбце - например, в таблице они с именем-отчеством или с пробелом лишним, или еще как). То есть, эта

Цитата Nic70y, 23.09.2014 в 11:00, в сообщении № 3

=СУММПРОИЗВ((F$2:H$4=A2)*$F$1:$H$1)

лучше

К сообщению приложен файл: 121212_1.xls (26.0 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Nic70y

Дата: Вторник, 23.09.2014, 11:00 | Сообщение № 3

Группа: Друзья

Ранг: Экселист

Сообщений: 8984

Репутация: 2359 ±

Замечаний: 0% ±

Excel 2010

Думаете чем формула короче, тем лучше?
ошибаетесь.

Код

=СУММПРОИЗВ((F$2:H$4=A2)*$F$1:$H$1)

а так красивее:

Код

=ЕЧИСЛО(ПОИСКПОЗ(A2;F$2:F$4;0))*F$1+ЕЧИСЛО(ПОИСКПОЗ(A2;G$2:G$4;0))*G$1+ЕЧИСЛО(ПОИСКПОЗ(A2;H$2:H$4;0))*H$1

+ Ваша:

Код

=ЕСЛИ(СЧЁТЕСЛИ($F$2:$F$4;A2);$F$1;ЕСЛИ(СЧЁТЕСЛИ($G$2:$G$4;A2);$G$1;ЕСЛИ(СЧЁТЕСЛИ($H$2:$H$4;A2);$H$1;"")))

склейте свою и мою:

Код

=ЕСЛИ(ЕЧИСЛО(ПОИСКПОЗ(A2;F$2:F$4;0));F$1;ЕСЛИ(ЕЧИСЛО(ПОИСКПОЗ(A2;G$2:G$4;0));G$1;ЕСЛИ(ЕЧИСЛО(ПОИСКПОЗ(A2;H$2:H$4;0));H$1;"")))

по-моему будет меньше всего тормозить.

ЮMoney 41001841029809

Ответить

ArkaIIIa

Дата: Вторник, 23.09.2014, 11:02 | Сообщение № 4

Группа: Проверенные

Ранг: Ветеран

Сообщений: 894

Репутация: 115 ±

Замечаний: 0% ±

2010

Цитата Nic70y, 23.09.2014 в 11:00, в сообщении № 3

Думаете чем формула короче, тем лучше?

Понимаю, что далеко не всегда это так, но, думаю, что формула, которую предложил Александр будет завешивать процесс значительно меньше, чем моя :-)

_Boroda_, Nic70y
Благодарю за оперативность и вариативность :-)

Апдейт. Раньше не замечал таймера на повышение репутации. Борода, я Вам чуть позже плюсану :-) спасибо еще раз за помощь!)