Sub обновление_сссылок()
     Dim V As String
     Dim BrowseFolder As String
     BrowseFolder = ThisWorkbook.Path & "\"
     'добавляем лист и выводим на него шапку таблицы
     '    Sheets("пути").Select
     With Worksheets("пути")
         .UsedRange.ClearContents
         With .Range("A1:E1")
             .Font.Bold = True
             .Font.Size = 12
         End With
         .Range("A1").Value = "Имя файла"
         .Range("B1").Value = "Путь"
         .Range("C1").Value = "Размер"
         .Range("D1").Value = "Дата создания"
         .Range("E1").Value = "Дата изменения"
     End With
     'вызываем процедуру вывода списка файлов
     'измените True на False, если не нужно выводить файлы из вложенных папок
     ListFilesInFolder BrowseFolder, True
     On Error Resume Next
     ThisWorkbook.Names("paths").Delete
     V = "=" & Sheets("пути").Range("b2:b" & Sheets("пути").[a65536].End(xlUp).Row).Address(external:=-1)
     ThisWorkbook.Names.Add Name:="paths", RefersTo:=V
     On Error GoTo 0
     With Sheets("текущий контракт").Range("F1").Validation
         .Delete
         .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Formula1:=Names("paths").RefersTo
         .IgnoreBlank = True
         .InCellDropdown = True
         .ShowInput = True
         .ShowError = True
     End With
End Sub

Private Sub ListFilesInFolder(ByVal SourceFolderName As String, ByVal IncludeSubfolders As Boolean)
     Dim FSO As Object
     Dim SourceFolder As Object
     Dim SubFolder As Object
     Dim FileItem As Object
     Dim r As Long
     Set FSO = CreateObject("Scripting.FileSystemObject")
     Set SourceFolder = FSO.getfolder(SourceFolderName)
     With Worksheets("пути")
         r = .Range("A65536").End(xlUp).Row + 1   'находим первую пустую строку
         'выводим данные по файлу
         For Each FileItem In SourceFolder.Files
             .Cells(r, 1).Formula = FileItem.Name
             .Cells(r, 2).Formula = FileItem.Path
             .Cells(r, 3).Formula = FileItem.Size
             .Cells(r, 4).Formula = FileItem.DateCreated
             .Cells(r, 5).Formula = FileItem.DateLastModified
             r = r + 1
             x = SourceFolder.Path
         Next FileItem
         'вызываем процедуру повторно для каждой вложенной папки
         If IncludeSubfolders Then
             For Each SubFolder In SourceFolder.SubFolders
                 ListFilesInFolder SubFolder.Path, True
             Next SubFolder
         End If
         .Columns("A:E").AutoFit
     End With
     Set FileItem = Nothing
     Set SourceFolder = Nothing
     Set FSO = Nothing
End Sub