поиск совпадений 2 ячейки/1 столбец с выводом мин и макс

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

поиск совпадений 2 ячейки/1 столбец с выводом мин и макс (Макросы/Sub)

Studentka86

Дата: Понедельник, 15.07.2019, 12:01 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 13

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

Добрый день, гуру!

Вновь остро нуждаюсь в вашей помощи.

Есть лист - прайс с наименованием товара, ценой в числовом формате и в виде текста.
На другом листе наименование товара из двух слов в разных столбцах (слова могут быть в обратной последовательности, слова и числа полностью - например, 10 и 100 это не совпадение, "мешок" и "меш" тоже разное).
Нужно найти точные совпадения и вывести в соседние ячейки мин и макс цену. Если совпадение только одно, то выводить цену в столбец мин.

Это можно реализовать для поиска по двум или трем словам?

В приложенном файле зеленой заливкой то, что должно получиться.

К сообщению приложен файл: ___2____min__ma.xlsx (11.5 Kb)

Сообщение отредактировал Studentka86 - Понедельник, 15.07.2019, 12:03

Ответить

_Boroda_

Дата: Понедельник, 15.07.2019, 12:30 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 16718

Репутация: 6505 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Так нужно?

Код

=ТЕКСТ(МИН(ЕСЛИ(ЕЧИСЛО(ПОИСК(" "&A2&" ";" "&прайс!A$2:A$99&" ")+ПОИСК(" "&B2&" ";" "&прайс!A$2:A$99&" "));прайс!B$2:B$99));"0\ руб.;;")

Код

=ТЕКСТ(МАКС(ЕЧИСЛО(ПОИСК(" "&A2&" ";" "&прайс!A$2:A$99&" ")+ПОИСК(" "&B2&" ";" "&прайс!A$2:A$99&" "))*прайс!B$2:B$99);"0\ руб.;;")

Код

=ИНДЕКС(прайс!A:A;МИН(99;ЕСЛИ(ЕЧИСЛО(ПОИСК(" "&A2&" ";" "&прайс!A$2:A$99&" ")+ПОИСК(" "&B2&" ";" "&прайс!A$2:A$99&" "))*(прайс!C$2:C$99=G2);СТРОКА(прайс!B$2:B$99))))&""

Код

=ИНДЕКС(прайс!A:A;ТЕКСТ(МАКС(ЕЧИСЛО(ПОИСК(" "&A2&" ";" "&прайс!A$2:A$99&" ")+ПОИСК(" "&B2&" ";" "&прайс!A$2:A$99&" "))*(прайс!C$2:C$99=H2)*СТРОКА(прайс!B$2:B$99));"0;;99"))&""

Формула массива. Вводится одновременным нажатием Ctrl+Shift+Enter
Для трех слов аналогично, только ПОИСК-ов не 2, а три будет

*Что-то ананасы у Вас не те в коробке

Вторые ананасы 10 (макс) можно убрать Условным форматированием (файл _2)

К сообщению приложен файл: _2_min_ma.xlsx (12.2 Kb) · _2_min_ma_2.xlsx (13.7 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Studentka86

Дата: Понедельник, 15.07.2019, 13:11 | Сообщение № 3

Группа: Пользователи

Ранг: Новичок

Сообщений: 13

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

Цитата _Boroda_, 15.07.2019 в 12:30, в сообщении № 2 ()

Так нужно?

Да! Вы - гений!
Думала, через формулы никак, поэтому тему в VBA создала.
Сделала сама для трех слов, все отлично работает!!!

*ананасы и вправду не те, вот что значит вручную проставлять, возникают ошибки, которых лишен электронный мозг

Спасибо!!!
Сейчас скину немножко спасибо на ЯД.

Ответить

поиск совпадений 2 ячейки/1 столбец с выводом мин и макс (Макросы/Sub)

Страница 1 из 1
1