Добавление значения к содержимому ячейки

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Добавление значения к содержимому ячейки (Макросы/Sub)

karmen185

Дата: Суббота, 24.11.2018, 02:56 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 41

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

Доброй ночи. Подскажите пожалуйста, как можно сделать, чтобы при нажатии кнопки, значение добавилось к предыдущему в ячейке В1. Думала формулой сцепить, но не подходит. Полный стопор, надо идти отдыхать. Спокойной ночи.

К сообщению приложен файл: 5846926.xls (57.5 Kb)

Ответить

krosav4ig

Дата: Суббота, 24.11.2018, 04:25 | Сообщение № 2

Группа: Друзья

Ранг: Старожил

Сообщений: 2347

Репутация: 997 ±

Замечаний: 0% ±

Excel 2007,2010,2013

Здравствуйте
переименовал кнопки в Digit0 .. Digit9, удалил код, привязанный к кнопкам
в модуле класса ClDigitalButtons
[vba]

Код

Private WithEvents cb As CommandButton
Private cell As Range
Public Sub Init(ctrl As CommandButton, r As Range)
    Set cb = ctrl
    Set cell = r
End Sub
Private Sub Class_Terminate()
    Set cb = Nothing
    Set cell = Nothing
End Sub
Private Sub cb_Click()
    cell = cell.Value & cb.Caption
End Sub

[/vba]в стандартном модуле
[vba]

Код

Dim colButtons As Collection
Sub hookButtons(ws As Object)
    Dim dBtn As ClDigitalButtons
    Dim obj As OLEObject
    Set colButtons = New Collection
    For Each obj In ws.OLEObjects
        If TypeOf obj.Object Is CommandButton And Left(obj.Name, 5) = "Digit" Then
            Set dBtn = New ClDigitalButtons
            dBtn.Init obj.Object, ws.[B1]
            colButtons.Add dBtn
        End If
    Next
End Sub

[/vba]в модуле ЭтаКнига[vba]

Код

Private Sub Workbook_Open()
hookButtons ActiveSheet
End Sub
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
hookButtons Sh
End Sub

[/vba]

К сообщению приложен файл: 0429301.xls (65.5 Kb)

email:krosav4ig26@gmail.com WMR R207627035142 WMZ Z821145374535 ЯД 410012026478460

Ответить

karmen185

Дата: Суббота, 24.11.2018, 08:59 | Сообщение № 3

Группа: Пользователи

Ранг: Новичок

Сообщений: 41

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

krosav4ig, здравствуйте. Но просто супер, я не думала, что для этого нужно столько кода. Тут уже целая работа. Укажите ваши реквизиты кошелька и сумму. Большое вам спасибо. hands

Ответить

Добавление значения к содержимому ячейки (Макросы/Sub)

Страница 1 из 1
1