='G:\Моя\Стереть\[3848898.xlsx]Все'!A1

=Сводный!A1

Sheets("Сводный").Range("a1:aa100").Value = Sheets("Куда скопировать").Range("a1:aa100").Value

Option Explicit
Const Filename$ = "C:\[путь к Excel'евскому файлу с данными]"
  
Sub DownloadData()
    Dim sSQL$: sSQL = "select * from [Лист1$]"  'имя защищенного листа с данными и "$"
    Dim CON As Object: Set CON = ExcelConnect(Filename)
    Dim RST As Object: Set RST = CreateObject("ADODB.Recordset")
    Dim MyArr()
    RST.Open Source:=sSQL, ActiveConnection:=CON
    If Not RST.EOF Then
        With ActiveSheet
'выгружаем все
        .Range("A1").CopyFromRecordset RST

' а можно конкретную ячейку выгрузить, например
'        MyArr = RST.GetRows
'        .Range("A1") = MyArr(3, 4)  '4-я строка, 5-й столбец
        End With
    Else
        ' Если нет данных то вывод сообщения:
        MsgBox "Нет данных удовлетворяющих условиям.", vbInformation + vbOKOnly, "Ошибка"
    End If
    Set RST = Nothing
    Set CON = Nothing
End Sub
  
Function ExcelConnect(ByVal PatchFile$, Optional TableHeader As Boolean = False) As Object
'TableHeader - Отметить True, если есть заголовки у таблицы и надо к столбцам обращаться по имени,
' иначе к столбцам можно обращаться F1, F2, F3 и т.д.
    Dim VersionFile$
    Dim strCon$
    Select Case Split(PatchFile, ".")(UBound(Split(PatchFile, ".")))
        Case "xls":  VersionFile = "Excel 8.0"
        Case "xlsb": VersionFile = "Excel 12.0"
        Case "xlsm": VersionFile = "Excel 12.0 Macro"
        Case "xlsx": VersionFile = "Excel 12.0 Xml"
    End Select
    strCon = "Provider=" & IIf(Val(Application.Version) > 11, "Microsoft.ACE.OLEDB.12.0", "Microsoft.Jet.OLEDB.4.0") & ";" & _
              "Data Source=""" & PatchFile & """;" & _
              "Extended Properties=""" & VersionFile & ";HDR=" & IIf(TableHeader, "YES", "NO") & """;"
    Set ExcelConnect = CreateObject("ADODB.Connection")
    ExcelConnect.Open strCon
End Function