Option Explicit

'Переменные для запоминания данных
Public wbWBook As Workbook
Public wsSh As Worksheet, wsActSh As Worksheet, sSh_Name As String, lShPoz As Long
'---------------------------------------------------------------------------------------
' Procedure : Вставить_строку
' Purpose : Основная процедура. Это тот код, который вносит изменения на лист
' и действия которого нам необходимо отменить
'---------------------------------------------------------------------------------------
Sub Вставить_строку()
Dim rCell As Range, li As Long
'Запоминаем активную книгу
'это на случай, если отмена действий будет производиться из другой книги
Set wbWBook = ActiveWorkbook
'Запоминаем активный лист
'на случай, если отмена действий будет производиться из другого листа
Set wsActSh = ActiveSheet
lShPoz = wsActSh.Index
sSh_Name = wsActSh.Name
Application.ScreenUpdating = 0

On Error Resume Next
Set wsSh = wbWBook.Sheets("резерв")
If Err.Number <> 0 Then
    Set wsSh = wbWBook.Sheets.Add(After:=wbWBook.Sheets(wbWBook.Sheets.Count))
    wsSh.Visible = xlVeryHidden
    wsSh.Name = "резерв"
End If
Err.Clear
On Error GoTo 0

wsActSh.Cells.Copy wsSh.[a1]
wsActSh.Activate
Application.ScreenUpdating = 1
'======================================
'Выполняем основные действия(собственно тот код, который надо будет отменить)
'
' Добавление строки
'
'ActiveSheet.Unprotect
With ActiveCell.EntireRow
.Offset(1).Insert
.Copy .Offset(1)
End With
Cells(ActiveCell.Row + 1, 1).Resize(, 3).ClearContents
Cells(ActiveCell.Row + 1, "K").Resize(, 2).ClearContents
'ActiveSheet.Protect
'======================================
'Назначаем стандартному вызову отмены действий выполнение нашего макроса возвращения значений
Application.OnUndo "Отменить макрос", "Откат"
End Sub

'---------------------------------------------------------------------------------------
' Procedure : Откат
' Purpose : Процедура отмены действия(возврат значений)
'---------------------------------------------------------------------------------------
Sub Откат()
'В случае непредвиденной ошибки переходим на метку
'и показываем сообщение об ошибке
'On Error GoTo Erreble
Application.ScreenUpdating = 0
'Активируем книгу, в которой были сделаны изменения
wbWBook.Activate
'делаем видимым резервный лист
wsSh.Visible = -1
'Удаляем исходный лист, данные в котором уже изменены
Application.DisplayAlerts = 0
wsActSh.Delete
'назначаем резервному листу имя исходного
wsSh.Name = sSh_Name
On Error Resume Next
wsSh.Move wbWBook.Sheets(lShPoz)
'Активируем резервный лист
wsSh.Activate
Application.ScreenUpdating = 0
Application.DisplayAlerts = True
Exit Sub
'Показываем сообщение о невозможности отмены действия
Erreble:
MsgBox "Нельзя отменить действие!", vbCritical, "Error"
End Sub