Удаление строк с пустыми ячейками - Мир MS Excel

Регистрация

Напомнить пароль

= Мир MS Excel/Удаление строк с пустыми ячейками - Мир MS Excel

Старая форма входа

Страница 1 из 3 1 2 3 »
Модератор форума: китин, _Boroda_

Удаление строк с пустыми ячейками

Удаление строк с пустыми ячейками

Дата: Вторник, 24.06.2014, 21:28 | Сообщение № 1

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

Всем привет.

Искал вариант попроще. Не нашёл, написал свой.

Следующий макрос на активном листе удаляет все строки, где в столбце А нет значения. Первая строка (заголовки) игнорируется.

[vba]

Код

Sub Row_Cleaner()
With ThisWorkbook.ActiveSheet

Dim Z As Long

For Z = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
If .Cells(Z, 1).Value = "" Then Rows(Z & ":" & Z).Delete Shift:=xlUp
Next Z

End With
End Sub

[/vba]

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Ответить

Дата: Вторник, 24.06.2014, 21:54 | Сообщение № 2

Группа: Друзья

Ранг: Старожил

Сообщений: 1906

Репутация: 504 ±

Замечаний: 0% ±

Excel 2003, 2010

Rioran, и этот макрос работает у Вас правильно?

помощь по Excel и VBA
ikki@fxmail.ru, icq 592842413, skype alex.ikki

Ответить

Дата: Вторник, 24.06.2014, 21:56 | Сообщение № 3

Группа: Друзья

Ранг: Экселист

Сообщений: 5660

Репутация: 1163 ±

Замечаний: 0% ±

2010

Я тоже сомнении. <_<

<_<

Быть или не быть, вот в чем загвоздка!

Ответить

Дата: Вторник, 24.06.2014, 21:59 | Сообщение № 4

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

ikki, да, мою задачу решает. В оригинале у меня вместо ActiveSheet стоит Sheets(1), но это не меняет сути.

Мне же надо было удалить те строки, для которых в ячейках столбца А пусто. What could go wrong?

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Ответить

Дата: Вторник, 24.06.2014, 22:02 | Сообщение № 5

Группа: Друзья

Ранг: Старожил

Сообщений: 1906

Репутация: 504 ±

Замечаний: 0% ±

Excel 2003, 2010

в принципе - он может сработать правильно.
если в столбце A нет двух и более подряд пустых ячеек.

помощь по Excel и VBA
ikki@fxmail.ru, icq 592842413, skype alex.ikki

Сообщение отредактировал ikki - Вторник, 24.06.2014, 22:03

Ответить

Дата: Вторник, 24.06.2014, 22:05 | Сообщение № 6

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

ikki, я всё осознал, иду исправлять

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Ответить

Дата: Вторник, 24.06.2014, 22:08 | Сообщение № 7

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

Госсссподи, Юпитер всемогущий, конечно же правильный вариант:

[vba]

Код

Sub Row_Cleaner()
With ThisWorkbook.ActiveSheet

Dim Z As Long

For Z = .Cells(Rows.Count, 1).End(xlUp).Row To 2 Step -1
If .Cells(Z, 1).Value = "" Then Rows(Z).Delete Shift:=xlUp
Next Z

End With
End Sub

[/vba]
Для начинающих экселистов - сравните два моих кода и найдите ошибку в логике первого кода yes

yes

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Сообщение отредактировал Rioran - Вторник, 24.06.2014, 22:15

Ответить

Дата: Вторник, 24.06.2014, 22:10 | Сообщение № 8

Группа: Друзья

Ранг: Старожил

Сообщений: 1906

Репутация: 504 ±

Замечаний: 0% ±

Excel 2003, 2010

кстати, вполне достаточно писать так: Rows(Z)

помощь по Excel и VBA
ikki@fxmail.ru, icq 592842413, skype alex.ikki

Ответить

Дата: Вторник, 24.06.2014, 22:15 | Сообщение № 9

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

ikki, спасибо, протестировал, убедился.

Заменил в посте № 32 громоздкое макро-рекодеровское Rows(Z & ":" & Z) на Ваше Rows(Z), так красивее =)

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Ответить

Дата: Вторник, 24.06.2014, 22:23 | Сообщение № 10

Группа: Друзья

Ранг: Старожил

Сообщений: 1906

Репутация: 504 ±

Замечаний: 0% ±

Excel 2003, 2010

Цитата Rioran, 24.06.2014 в 21:28, в сообщении № 26

Искал вариант попроще

может, так?[vba]

Код

Sub test()
     On Error Resume Next
     With Sheets(1)
         .Range(.[a2], .Cells(.Rows.Count, 1).End(xlUp)).SpecialCells(4).EntireRow.Delete
     End With
End Sub

[/vba]

помощь по Excel и VBA
ikki@fxmail.ru, icq 592842413, skype alex.ikki

Ответить

Дата: Вторник, 24.06.2014, 22:40 | Сообщение № 11

Группа: Друзья

Ранг: Экселист

Сообщений: 5660

Репутация: 1163 ±

Замечаний: 0% ±

2010

При всем моем уважении
Вам кажется, что ГОТОВЫЕ решения , это именно то место, где есть смысл обсуждать подобные вопросы?
Может есть смысл попросить модераторов почистить?

Быть или не быть, вот в чем загвоздка!

Ответить

Дата: Вторник, 24.06.2014, 22:51 | Сообщение № 12

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

ikki, классный метод, красиво! =)
RAN, здесь как раз обсуждается именно готовое решение по теме. Готовое решение предложено, теме соответствует. Что не так?

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Сообщение отредактировал Rioran - Вторник, 24.06.2014, 22:53

Ответить

Дата: Вторник, 24.06.2014, 23:26 | Сообщение № 13

Группа: Друзья

Ранг: Экселист

Сообщений: 5660

Репутация: 1163 ±

Замечаний: 0% ±

2010

Ну хотя бы то, что предложенный макрос не соответствует теме, т.е. не удаляет пустые строки. (в т.ч и макрос ikki)

Быть или не быть, вот в чем загвоздка!

Ответить

Дата: Среда, 25.06.2014, 00:45 | Сообщение № 14

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

RAN, с этой точки зрения да, вопрос обсуждаем другой, хоть и смежный. Похоже, было бы лучше новую тему открыть, да поздно.

******

О, спасибо, перенесли! =)

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Сообщение отредактировал Rioran - Среда, 25.06.2014, 11:54

Ответить

Дата: Среда, 25.06.2014, 01:38 | Сообщение № 15

Группа: Админы

Ранг: Местный житель

Сообщений: 16800

Репутация: 6558 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Внесу и свои 5 копеек.

Цитата ikki, 24.06.2014 в 22:23, в сообщении № 35

SpecialCells(4).EntireRow.Delete

Это был мой любимый способ до той поры, пока я не попался на ограничение Excelя. При достаточно большом количестве несвязанных диапазонов в SpecialCells этот метод правильно не работает. Тут (на форуме) это уже неоднократно обсуждалось.

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Дата: Среда, 25.06.2014, 09:24 | Сообщение № 16

Группа: Друзья

Ранг: Участник клуба

Сообщений: 3219

Репутация: 622 ±

Замечаний: 0% ±

2003

Цитата RAN, 24.06.2014 в 22:40, в сообщении № 36

Может есть смысл попросить модераторов почистить?

Абсолютно согласен.
Это всё оффтоп, т.к. посвящено не полировке сабжа топика, а переделке его "под себя". Хотите об этом поговорить? Создавайте топик в соответствующем разделе форума .
_Boroda_, Саша, ты же сам модератор и своим постом поощряешь офтопп и флуд?
[offtop]А по поводу SpecialCells, так с ними вообще нужно очень аккуратно, т.к. у этого свойства имеется гнусное свойство

- если в диапазоне, для которого запрашиваешь SpecialCells, более одной ячейки, то всё работает нормально и выбираются только нужные ячейки этого диапазона. А вот если в диапазоне всего одна ячейка, то SpecialCells выбирают ВСЕ ячейки листа, удовлетворяющие условиям.[/offtop]

С уважением,
Алексей
MS Excel 2003 - the best!!!

Ответить

Дата: Среда, 25.06.2014, 09:57 | Сообщение № 17

Группа: Админы

Ранг: Местный житель

Сообщений: 16800

Репутация: 6558 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Цитата Alex_ST, 25.06.2014 в 09:24, в сообщении № 16

Саша, ты же сам модератор и своим постом поощряешь офтопп и флуд?

Бе-бе-бе.

Все равно тему чистить нужно было. А мне вчера лениво было дележкой заниматься.

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

Дата: Среда, 25.06.2014, 11:58 | Сообщение № 18

Группа: Авторы

Ранг: Ветеран

Сообщений: 903

Репутация: 290 ±

Замечаний: 0% ±

Excel 2013

_Boroda_, спасибо за отделение зёрен от ~~плевел~~ зёрен

Alex_ST, ikki, _Boroda_, получается, что надёжнее код из поста № 7, поочерёдно перебирающий ячейки первого столбца?

Роман, Москва, voronov_rv@mail.ru
Яндекс-Деньги: 41001312674279

Сообщение отредактировал Rioran - Среда, 25.06.2014, 11:58

Ответить

Дата: Среда, 25.06.2014, 12:14 | Сообщение № 19

Группа: Друзья

Ранг: Экселист

Сообщений: 5660

Репутация: 1163 ±

Замечаний: 0% ±

2010

[vba]

Код

Sub Мяу()
     For i = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
         If Len(Cells(i, 1)) Then
         Else
             If r Is Nothing Then
                 Set r = Rows(i)
             Else
                 Set r = Union(r, Rows(i))
             End If
         End If
     Next
     r.Delete
End Sub

[/vba]

Быть или не быть, вот в чем загвоздка!

Ответить

Дата: Среда, 25.06.2014, 12:24 | Сообщение № 20

Группа: Друзья

Ранг: Старожил

Сообщений: 1206

Репутация: 255 ±

Замечаний: 0% ±

2010

Ну и я вариант предложу

[vba]

Код

Sub deleteEmptyRows()
Dim x, i&, delRa As Range
x = Range("A1:A" & [a65535].End(xlUp).Row).Value
      For i = 1 To UBound(x)
          If x(i, 1) = "" Then
              If delRa Is Nothing Then
                  Set delRa = Cells(i, 1)
              Else
                  Set delRa = Union(Cells(i, 1), delRa)
              End If
          End If
      Next
If Not delRa Is Nothing Then delRa.EntireRow.Delete
End Sub

[/vba]
Для офиса младше 2007 [a65535] заменить на [A1048576].

skypro1111@gmail.com

Сообщение отредактировал SkyPro - Среда, 25.06.2014, 12:26

Ответить

Удаление строк с пустыми ячейками

Страница 1 из 3
1
2
3
»

© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!