' Функция "text_to_Voice" позволяет использовать голосовые сообщения
' в ваших программах VBA,
' независимо от наличия голосовых движков на машине пользователя,
' при наличии выхода в Интернет, используя "облачные технологии",
' и услуги предоставляемые на страничке "http://www.linguatec.de/voice-reader-home-15-demo/"

' При использовании "text_to_Voice" в других книгах
' В модуле "Эта книга" не забудьте разместить следующий код:
'  Private Sub Workbook_BeforeClose(Cancel As Boolean)
'    IE_Quit
'  End Sub
'
'Полезные ссылки:
'http://www.excelworld.ru/forum/10-8090-1
'https://technet.microsoft.com/en-us/aa752043
Dim IE As Object

Public Sub text_to_Voice(voice As Integer, myStr As String)
' myStr - строка озвучки до 255 символов
' voice - тип голоса 0 = жен.
'                          1 = муж.
Dim sURL As String, testhWnd As Long
sURL = "http://www.linguatec.de/voice-reader-home-15-demo/"
On Error Resume Next
    testhWnd = IE.hWnd 'проверка на существование IE
    If Err.Number <> 0 Then ' если IE не существует
        Set IE = CreateObject("InternetExplorer.Application")    ' open Internet Explorer
         With IE
          .Visible = False 'видимость
          .Navigate sURL  ' переход
                While .Busy Or (.readyState <> 4): DoEvents: Wend    ' ожидание
                Set ieDoc = .document
             If ieDoc.Title Like "Ошибка сертификата*" Or ieDoc.Title Like "Certificate Error*" Then
                ieDoc.Links(1).Click
                While IE.Busy Or (IE.readyState <> 4): DoEvents: Wend
             End If
          End With
    End If
On Error GoTo err0
'-------------------------------------------------------------
       Set ieDoc = IE.document
       With ieDoc
             .getElementByID("vr_LanguageSelector").Value = "ru-ru"
             .getElementByID("vr_LanguageSelector").onChange
        If voice = 0 Then
             .getElementByID("vr_VoiceSelector").Value = "Milena"
        Else
             .getElementByID("vr_VoiceSelector").Value = "Yuri"
        End If
             .getElementByID("vr_SampleText").Value = myStr
             .getElementByID("vr_ReadButton").Click
         End With
Exit Sub
err0:
  MsgBox "Ошибка в text_to_Voice"
End Sub

Public Sub IE_Quit()
' При использовании "text_to_Voice" в других книгах
' В модуле "Эта книга" не забудьте разместить следующий код:
'  Private Sub Workbook_BeforeClose(Cancel As Boolean)
'    IE_Quit
'  End Sub
On Error Resume Next
IE.Quit
End Sub

'=============================
'Примеры использования "text_to_Voice"
Public Sub V_test0()
Call text_to_Voice(0, " Соединение со спутниками установлено успешно")
Application.Wait (Now + TimeValue("0:00:04"))
'или так
text_to_Voice 1, " привет"
Application.Wait (Now + TimeValue("0:00:01"))
text_to_Voice 0, " Теперь вы сможете оснастить свою программу голосовыми сообщениями, и примечаниями"
End Sub

Public Sub V_test1()
'или так
text_to_Voice 0, ActiveCell.Value
End Sub