Function Rio_Investigates_Formula(FormulaX As Range, LevelX As Long) As String

Dim arrX As Variant 'Array with single symbols for each row
Dim strX As String 'To work with Formula string
Dim A As Long 'How long formula is
Dim X As Long 'To roll arrX
Dim DeepX As Long 'How deep are we
Dim LevelCheck As Byte 'To control where to place [[...]]

strX = FormulaX.FormulaLocal

A = Len(strX) - 1
strX = Right(strX, A)
DeepX = 1
LevelCheck = 1

ReDim arrX(A, 3)
        
For X = 1 To A
      arrX(X, 1) = Mid(strX, X, 1)
      Select Case arrX(X, 1)
          Case "("
              arrX(X, 2) = DeepX
              DeepX = DeepX + 1
              If arrX(X, 2) = LevelX Then arrX(X, 1) = "   <<<   "
          Case ")"
              DeepX = DeepX - 1
              arrX(X, 2) = DeepX
              If arrX(X, 2) = LevelX Then arrX(X, 1) = "   >>>   "
          Case ";"
              arrX(X, 2) = DeepX
              arrX(X, 3) = 1
              If arrX(X, 2) = LevelX + 1 Then arrX(X, 1) = "   ...[и]...   "
          Case Else
              arrX(X, 2) = DeepX
      End Select
      If LevelX <= arrX(X, 2) Then
          Rio_Investigates_Formula = Rio_Investigates_Formula & arrX(X, 1)
          LevelCheck = 1
      Else
          If LevelCheck = 1 Then
              LevelCheck = 0
              Rio_Investigates_Formula = Rio_Investigates_Formula & "   [[...]]   "
          End If
      End If
Next X

Rio_Investigates_Formula = Application.Substitute(Rio_Investigates_Formula, ";", "  ;  ")
Rio_Investigates_Formula = Application.Substitute(Rio_Investigates_Formula, "(", "  (  ")
Rio_Investigates_Formula = Application.Substitute(Rio_Investigates_Formula, ")", "  )  ")

End Function

Private Sub Rio_ReColor(rngR As Range)

Dim A As Long 'To roll rngR symbols

For A = 1 To Len(rngR.Value)
      Select Case Mid(rngR.Value, A, 1)
          Case "<"
              If Mid(rngR.Value, A + 1, 1) = "<" Then
                  With rngR.Characters(Start:=A, Length:=3).Font
                      .FontStyle = "полужирный"
                      .Color = -16776961
                  End With
                  A = A + 2
              End If
          Case ">"
              If Mid(rngR.Value, A + 1, 1) = ">" Then
                  With rngR.Characters(Start:=A, Length:=3).Font
                      .FontStyle = "полужирный"
                      .Color = -16776961
                  End With
                  A = A + 2
              End If
          Case "["
              Select Case Mid(rngR.Value, A + 1, 1)
                  Case "и"
                      With rngR.Characters(Start:=(A - 3), Length:=9).Font
                          .FontStyle = "полужирный"
                          .Color = -16776961
                      End With
                      A = A + 5
                  Case "["
                      With rngR.Characters(Start:=A, Length:=7).Font
                          .FontStyle = "полужирный"
                          .Color = -16776961
                      End With
                      A = A + 6
              End Select
      End Select
Next A

End Sub