Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Возврат значения из таблицы по нескольким критериям - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Возврат значения из таблицы по нескольким критериям (Формулы/Formulas)
Возврат значения из таблицы по нескольким критериям
GiroMan Дата: Вторник, 08.08.2023, 17:31 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 20% ±

2010,2016,2021
Здравствуйте!
Ломаю голову над такой ситуацией, если большая таблица с где много столбцов, среди них есть три, с помощью которых нужно получит нужные данные.
Для примера сократил до трех этих столбцов. Пример тип-производитель-цена.
Как из таблицы вернуть название производителя исходя из минимальной цены, но что бы это был конкретный тип.
То есть, я могу использовать формулу
Код
=ИНДЕКС(B2:B7;ПОИСКПОЗ(МИН(C2:C7);C2:C7;0))
, но она смотрит всю таблицу и вернет производителя любого типа с минимальной ценой, а мне нужно, что бы отбирала только нужный мне тип. как если бы я использовал.
Код
=ЕСЛИ

Я честно пытался соорудить подобающую формулу, но ничего не вышло(
Буду очень благодарен за помощь!
Прикреплю пример.
К сообщению приложен файл: test.xlsx (10.0 Kb)


Сообщение отредактировал GiroMan - Вторник, 08.08.2023, 17:32
 
Ответить
СообщениеЗдравствуйте!
Ломаю голову над такой ситуацией, если большая таблица с где много столбцов, среди них есть три, с помощью которых нужно получит нужные данные.
Для примера сократил до трех этих столбцов. Пример тип-производитель-цена.
Как из таблицы вернуть название производителя исходя из минимальной цены, но что бы это был конкретный тип.
То есть, я могу использовать формулу
Код
=ИНДЕКС(B2:B7;ПОИСКПОЗ(МИН(C2:C7);C2:C7;0))
, но она смотрит всю таблицу и вернет производителя любого типа с минимальной ценой, а мне нужно, что бы отбирала только нужный мне тип. как если бы я использовал.
Код
=ЕСЛИ

Я честно пытался соорудить подобающую формулу, но ничего не вышло(
Буду очень благодарен за помощь!
Прикреплю пример.
Автор - GiroMan
Дата добавления - 08.08.2023 в 17:31
bigor Дата: Вторник, 08.08.2023, 17:47 | Сообщение № 2
Группа: Проверенные
Ранг: Старожил
Сообщений: 1271
Репутация: 244 ±
Замечаний: 0% ±

нет
GiroMan, добрый день, пробуйте, массивная. Так как таблица у вас не очень, то типы нужно в формуле прописывать, если бы они были в шапке явно, то можно было бы оттуда брать
Код
=INDEX($B$2:$B$7;MATCH(MINIFS($C$2:$C$7;$A$2:$A$7;$A$2)&$A$2;$C$2:$C$7&$A$2:$A$7;0))
К сообщению приложен файл: test_1_1.xlsx (7.8 Kb)


Сообщение отредактировал bigor - Вторник, 08.08.2023, 17:48
 
Ответить
СообщениеGiroMan, добрый день, пробуйте, массивная. Так как таблица у вас не очень, то типы нужно в формуле прописывать, если бы они были в шапке явно, то можно было бы оттуда брать
Код
=INDEX($B$2:$B$7;MATCH(MINIFS($C$2:$C$7;$A$2:$A$7;$A$2)&$A$2;$C$2:$C$7&$A$2:$A$7;0))
Автор - bigor
Дата добавления - 08.08.2023 в 17:47
GiroMan Дата: Среда, 09.08.2023, 10:29 | Сообщение № 3
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 20% ±

2010,2016,2021
Благодарю вас! Все работает!


Сообщение отредактировал Serge_007 - Среда, 09.08.2023, 10:46
 
Ответить
СообщениеБлагодарю вас! Все работает!
Автор - GiroMan
Дата добавления - 09.08.2023 в 10:29
Pelena Дата: Среда, 09.08.2023, 13:48 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 19404
Репутация: 4555 ±
Замечаний: ±

Excel 365 & Mac Excel
Можно ещё для новых версий Excel
Код
=ФИЛЬТР($B$2:$B$7;($A$2:$A$7=F1)*($C$2:$C$7=МИНЕСЛИ($C$2:$C$7;$A$2:$A$7;F1)))

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеМожно ещё для новых версий Excel
Код
=ФИЛЬТР($B$2:$B$7;($A$2:$A$7=F1)*($C$2:$C$7=МИНЕСЛИ($C$2:$C$7;$A$2:$A$7;F1)))
Автор - Pelena
Дата добавления - 09.08.2023 в 13:48
Светлый Дата: Среда, 09.08.2023, 15:16 | Сообщение № 5
Группа: Друзья
Ранг: Старожил
Сообщений: 1851
Репутация: 523 ±
Замечаний: 0% ±

Excel 2013, 2016
И для старых версий Excel.
Код
=ИНДЕКС($B$2:$C$9;ПОИСКПОЗ(МИН(ЕСЛИ($A$2:$A$9=F$1;$C$2:$C$9));ЕСЛИ($A$2:$A$9=F$1;$C$2:$C$9););СТРОКА(F1))
К сообщению приложен файл: test_1_2.xlsx (10.8 Kb)

Программировать проще, чем писать стихи.
 
Ответить
СообщениеИ для старых версий Excel.
Код
=ИНДЕКС($B$2:$C$9;ПОИСКПОЗ(МИН(ЕСЛИ($A$2:$A$9=F$1;$C$2:$C$9));ЕСЛИ($A$2:$A$9=F$1;$C$2:$C$9););СТРОКА(F1))
Автор - Светлый
Дата добавления - 09.08.2023 в 15:16
jakim Дата: Четверг, 10.08.2023, 07:10 | Сообщение № 6
Группа: Друзья
Ранг: Старожил
Сообщений: 1216
Репутация: 316 ±
Замечаний: 0% ±

Excel 2010
Формула

Код
=INDEX($B3:$B8;AGGREGATE(15;6;ROW($1:$25)/($C3:$C8=AGGREGATE(15;6;$C3:$C8/($A3:$A8=F2);1));1))
К сообщению приложен файл: test_2.xlsx (10.7 Kb)
 
Ответить
Сообщение
Формула

Код
=INDEX($B3:$B8;AGGREGATE(15;6;ROW($1:$25)/($C3:$C8=AGGREGATE(15;6;$C3:$C8/($A3:$A8=F2);1));1))
Автор - jakim
Дата добавления - 10.08.2023 в 07:10
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Возврат значения из таблицы по нескольким критериям (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!