Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Дата оплаты со сложными условиями - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Дата оплаты со сложными условиями (Формулы/Formulas)
Дата оплаты со сложными условиями
anya87 Дата: Среда, 16.10.2019, 17:48 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 8
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Добрый день. Прошу помочь прописать формулу (самой не получается до нее дойти).
Нужно посчитать предполагаемую дату оплаты счетов, если по договору отсрочка 75 календарных дней, но платежный день - первый или второй вторник месяца.
К сообщению приложен файл: 5098680.xls (34.0 Kb)


Сообщение отредактировал anya87 - Среда, 16.10.2019, 17:49
 
Ответить
СообщениеДобрый день. Прошу помочь прописать формулу (самой не получается до нее дойти).
Нужно посчитать предполагаемую дату оплаты счетов, если по договору отсрочка 75 календарных дней, но платежный день - первый или второй вторник месяца.
Автор - anya87
Дата добавления - 16.10.2019 в 17:48
Kostya_Ye Дата: Среда, 16.10.2019, 19:18 | Сообщение № 2
Группа: Проверенные
Ранг: Обитатель
Сообщений: 271
Репутация: 228 ±
Замечаний: 0% ±

Excel 2016
anya87, добрый день,
каким условием будут определяться - первый или второй вторник ?
вторник должен быть в пределах 75 дней или после ?
в примере вручную укажите какую дату хотите получить и вам предложат формулу.
 
Ответить
Сообщениеanya87, добрый день,
каким условием будут определяться - первый или второй вторник ?
вторник должен быть в пределах 75 дней или после ?
в примере вручную укажите какую дату хотите получить и вам предложат формулу.
Автор - Kostya_Ye
Дата добавления - 16.10.2019 в 19:18
bmv98rus Дата: Среда, 16.10.2019, 20:37 | Сообщение № 3
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
Цитата Kostya_Ye, 16.10.2019 в 19:18, в сообщении № 2 ()
в пределах 75
иначе это нарушение договора.

Замечательный Временно просто медведь , процентов на 20.
 
Ответить
Сообщение
Цитата Kostya_Ye, 16.10.2019 в 19:18, в сообщении № 2 ()
в пределах 75
иначе это нарушение договора.
Автор - bmv98rus
Дата добавления - 16.10.2019 в 20:37
Pelena Дата: Среда, 16.10.2019, 21:40 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 19392
Репутация: 4537 ±
Замечаний: ±

Excel 365 & Mac Excel
Код
=ЕСЛИ(A2+B2<ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);1)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2)-1;8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ЕСЛИ(A2+B2<ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);1)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7)))
К сообщению приложен файл: 2501616.xls (36.5 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
Сообщение
Код
=ЕСЛИ(A2+B2<ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);1)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2)-1;8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ЕСЛИ(A2+B2<ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);1)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7);ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2);8)+ОСТАТ(2-ДАТА(ГОД(A2+B2);МЕСЯЦ(A2+B2););7)))
Автор - Pelena
Дата добавления - 16.10.2019 в 21:40
bmv98rus Дата: Среда, 16.10.2019, 23:17 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
Pelena, Елена, первое число месяца -
Код
=EOMONTH(A2+B2,-1)+1

Замечательный Временно просто медведь , процентов на 20.
 
Ответить
СообщениеPelena, Елена, первое число месяца -
Код
=EOMONTH(A2+B2,-1)+1
Автор - bmv98rus
Дата добавления - 16.10.2019 в 23:17
Pelena Дата: Четверг, 17.10.2019, 08:28 | Сообщение № 6
Группа: Админы
Ранг: Местный житель
Сообщений: 19392
Репутация: 4537 ±
Замечаний: ±

Excel 365 & Mac Excel
Михаил, не поняла Вас

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеМихаил, не поняла Вас
Автор - Pelena
Дата добавления - 17.10.2019 в 08:28
bmv98rus Дата: Четверг, 17.10.2019, 09:06 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
Pelena, Конструкции
Код
=DATE(YEAR(A2+B2),MONTH(A2+B2),1)
меняется на
Код
=EOMONTH(A2+B2,-1)+1
Код
=DATE(YEAR(A2+B2),MONTH(A2+B2),)
, на
Код
=EOMONTH(A2+B2,-1)
чуть компактнее
Там еще и ошибка закралась, пометил в файле
мой вариант
Код
=LOOKUP(A2+B2;CHOOSE({1;2;3;4};EOMONTH(A2+B2;-2)+8-WEEKDAY(EOMONTH(A2+B2;-2)+1;13);EOMONTH(A2+B2;-2)+15-WEEKDAY(EOMONTH(A2+B2;-2)+1;13);EOMONTH(A2+B2;-1)+8-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;-1)+15-WEEKDAY(EOMONTH(A2+B2;-1)+1;13)))

Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Четверг, 17.10.2019, 11:51
 
Ответить
СообщениеPelena, Конструкции
Код
=DATE(YEAR(A2+B2),MONTH(A2+B2),1)
меняется на
Код
=EOMONTH(A2+B2,-1)+1
Код
=DATE(YEAR(A2+B2),MONTH(A2+B2),)
, на
Код
=EOMONTH(A2+B2,-1)
чуть компактнее
Там еще и ошибка закралась, пометил в файле
мой вариант
Код
=LOOKUP(A2+B2;CHOOSE({1;2;3;4};EOMONTH(A2+B2;-2)+8-WEEKDAY(EOMONTH(A2+B2;-2)+1;13);EOMONTH(A2+B2;-2)+15-WEEKDAY(EOMONTH(A2+B2;-2)+1;13);EOMONTH(A2+B2;-1)+8-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;-1)+15-WEEKDAY(EOMONTH(A2+B2;-1)+1;13)))
Автор - bmv98rus
Дата добавления - 17.10.2019 в 09:06
anya87 Дата: Четверг, 17.10.2019, 10:52 | Сообщение № 8
Группа: Пользователи
Ранг: Прохожий
Сообщений: 8
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Цитата Kostya_Ye, 16.10.2019 в 19:18, в сообщении № 2 ()
вторник должен быть в пределах 75 дней или после ?

оплата должна быть не ранее 75 дней, то есть оплата после 75 дней, но в первый или второй вторник месяца.

В приложенном файле вручную посчитала необходимую дату.
К сообщению приложен файл: 8485589.xls (34.5 Kb)


Сообщение отредактировал anya87 - Четверг, 17.10.2019, 10:58
 
Ответить
Сообщение
Цитата Kostya_Ye, 16.10.2019 в 19:18, в сообщении № 2 ()
вторник должен быть в пределах 75 дней или после ?

оплата должна быть не ранее 75 дней, то есть оплата после 75 дней, но в первый или второй вторник месяца.

В приложенном файле вручную посчитала необходимую дату.
Автор - anya87
Дата добавления - 17.10.2019 в 10:52
anya87 Дата: Четверг, 17.10.2019, 10:59 | Сообщение № 9
Группа: Пользователи
Ранг: Прохожий
Сообщений: 8
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Цитата bmv98rus, 16.10.2019 в 20:37, в сообщении № 3 ()
иначе это нарушение договора.

Простите. что запутала. По договору минимум 75 дней.
 
Ответить
Сообщение
Цитата bmv98rus, 16.10.2019 в 20:37, в сообщении № 3 ()
иначе это нарушение договора.

Простите. что запутала. По договору минимум 75 дней.
Автор - anya87
Дата добавления - 17.10.2019 в 10:59
bmv98rus Дата: Четверг, 17.10.2019, 11:21 | Сообщение № 10
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
то есть дата оплаты это ближайший следующий за датой вторник, первый или второй в месяце.

Замечательный Временно просто медведь , процентов на 20.
 
Ответить
Сообщението есть дата оплаты это ближайший следующий за датой вторник, первый или второй в месяце.
Автор - bmv98rus
Дата добавления - 17.10.2019 в 11:21
anya87 Дата: Четверг, 17.10.2019, 11:33 | Сообщение № 11
Группа: Пользователи
Ранг: Прохожий
Сообщений: 8
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Цитата bmv98rus, 17.10.2019 в 11:21, в сообщении № 10 ()
то есть дата оплаты это ближайший следующий за датой вторник, первый или второй в месяце.

Все верно.
 
Ответить
Сообщение
Цитата bmv98rus, 17.10.2019 в 11:21, в сообщении № 10 ()
то есть дата оплаты это ближайший следующий за датой вторник, первый или второй в месяце.

Все верно.
Автор - anya87
Дата добавления - 17.10.2019 в 11:33
bmv98rus Дата: Четверг, 17.10.2019, 11:51 | Сообщение № 12
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
Код
=-LOOKUP(-INT(A2+B2);-CHOOSE({4;3;2;1};EOMONTH(A2+B2;-1)+8-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;-1)+15-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;0)+8-WEEKDAY(EOMONTH(A2+B2;0)+1;13);EOMONTH(A2+B2;0)+15-WEEKDAY(EOMONTH(A2+B2;0)+1;13)))

Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Четверг, 17.10.2019, 12:39
 
Ответить
Сообщение
Код
=-LOOKUP(-INT(A2+B2);-CHOOSE({4;3;2;1};EOMONTH(A2+B2;-1)+8-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;-1)+15-WEEKDAY(EOMONTH(A2+B2;-1)+1;13);EOMONTH(A2+B2;0)+8-WEEKDAY(EOMONTH(A2+B2;0)+1;13);EOMONTH(A2+B2;0)+15-WEEKDAY(EOMONTH(A2+B2;0)+1;13)))
Автор - bmv98rus
Дата добавления - 17.10.2019 в 11:51
Nic70y Дата: Четверг, 17.10.2019, 12:08 | Сообщение № 13
Группа: Друзья
Ранг: Экселист
Сообщений: 8984
Репутация: 2359 ±
Замечаний: 0% ±

Excel 2010
аналогичный результат
Код
=КОНМЕСЯЦА(C2;ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;8});-1;0))+ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;1;8});1;8;1)+ОСТАТ(9-ДЕНЬНЕД(КОНМЕСЯЦА(C2;ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;8});-1;0))+1;2);7)
неправильно,
отвлекают гады на работе

ЮMoney 41001841029809

Сообщение отредактировал Nic70y - Четверг, 17.10.2019, 12:37
 
Ответить
Сообщениеаналогичный результат
Код
=КОНМЕСЯЦА(C2;ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;8});-1;0))+ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;1;8});1;8;1)+ОСТАТ(9-ДЕНЬНЕД(КОНМЕСЯЦА(C2;ВЫБОР(ПОИСКПОЗ(МАКС(0;ОКРУГЛВНИЗ(C2-H2;));{0;8});-1;0))+1;2);7)
неправильно,
отвлекают гады на работе
Автор - Nic70y
Дата добавления - 17.10.2019 в 12:08
anya87 Дата: Четверг, 17.10.2019, 12:22 | Сообщение № 14
Группа: Пользователи
Ранг: Прохожий
Сообщений: 8
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Супер, спасибо вам.
 
Ответить
СообщениеСупер, спасибо вам.
Автор - anya87
Дата добавления - 17.10.2019 в 12:22
bmv98rus Дата: Четверг, 17.10.2019, 12:37 | Сообщение № 15
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
ну тогда так
Код
=-LOOKUP(-INT(A2+B2);-(EOMONTH(A2+B2;{0;0;-1;-1})+{15;8;15;8}-WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)))
или
Код
=-LOOKUP(1-A2-B2;-(EOMONTH(A2+B2;{0;0;-1;-1})+{15;8;15;8}-WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)))

и совсем коротенько
Код
=-LOOKUP(1-A2-B2;WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)-EOMONTH(A2+B2;{0;0;-1;-1})-{15;8;15;8})
К сообщению приложен файл: Copy_of_1196.xlsx (19.6 Kb)

Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Четверг, 17.10.2019, 12:41
 
Ответить
Сообщениену тогда так
Код
=-LOOKUP(-INT(A2+B2);-(EOMONTH(A2+B2;{0;0;-1;-1})+{15;8;15;8}-WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)))
или
Код
=-LOOKUP(1-A2-B2;-(EOMONTH(A2+B2;{0;0;-1;-1})+{15;8;15;8}-WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)))

и совсем коротенько
Код
=-LOOKUP(1-A2-B2;WEEKDAY(EOMONTH(A2+B2;{0;0;-1;-1})+1;13)-EOMONTH(A2+B2;{0;0;-1;-1})-{15;8;15;8})
Автор - bmv98rus
Дата добавления - 17.10.2019 в 12:37
Kostya_Ye Дата: Четверг, 17.10.2019, 14:17 | Сообщение № 16
Группа: Проверенные
Ранг: Обитатель
Сообщений: 271
Репутация: 228 ±
Замечаний: 0% ±

Excel 2016
bmv98rus,
Класс !!!
не-е-е, Высший Класс !!
 
Ответить
Сообщениеbmv98rus,
Класс !!!
не-е-е, Высший Класс !!
Автор - Kostya_Ye
Дата добавления - 17.10.2019 в 14:17
Pelena Дата: Четверг, 17.10.2019, 17:36 | Сообщение № 17
Группа: Админы
Ранг: Местный житель
Сообщений: 19392
Репутация: 4537 ±
Замечаний: ±

Excel 365 & Mac Excel
Цитата anya87, 17.10.2019 в 10:52, в сообщении № 8 ()
оплата должна быть не ранее 75 дней

А я-то поверила Михаилу
Цитата bmv98rus, 16.10.2019 в 20:37, в сообщении № 3 ()
в пределах 75
иначе это нарушение договора
и считала не позднее 75 дней

Цитата bmv98rus, 17.10.2019 в 09:06, в сообщении № 7 ()
меняется на
формулу взяла готовую для любого по счёту дня недели, а уж сокращать некогда было

Цитата Kostya_Ye, 17.10.2019 в 14:17, в сообщении № 16 ()
Класс !!!
Присоединяюсь)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
Сообщение
Цитата anya87, 17.10.2019 в 10:52, в сообщении № 8 ()
оплата должна быть не ранее 75 дней

А я-то поверила Михаилу
Цитата bmv98rus, 16.10.2019 в 20:37, в сообщении № 3 ()
в пределах 75
иначе это нарушение договора
и считала не позднее 75 дней

Цитата bmv98rus, 17.10.2019 в 09:06, в сообщении № 7 ()
меняется на
формулу взяла готовую для любого по счёту дня недели, а уж сокращать некогда было

Цитата Kostya_Ye, 17.10.2019 в 14:17, в сообщении № 16 ()
Класс !!!
Присоединяюсь)
Автор - Pelena
Дата добавления - 17.10.2019 в 17:36
bmv98rus Дата: Четверг, 17.10.2019, 17:42 | Сообщение № 18
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4112
Репутация: 769 ±
Замечаний: 0% ±

Excel 2013/2016
Цитата Pelena, 17.10.2019 в 17:36, в сообщении № 17 ()
А я-то поверила Михаилу

я сам себе поверил :D Ваще не позднее чем обычно, но тут какие то льготные не ранее чем :D
Цитата Pelena, 17.10.2019 в 17:36, в сообщении № 17 ()
Присоединяюсь)
Cпс.

Замечательный Временно просто медведь , процентов на 20.
 
Ответить
Сообщение
Цитата Pelena, 17.10.2019 в 17:36, в сообщении № 17 ()
А я-то поверила Михаилу

я сам себе поверил :D Ваще не позднее чем обычно, но тут какие то льготные не ранее чем :D
Цитата Pelena, 17.10.2019 в 17:36, в сообщении № 17 ()
Присоединяюсь)
Cпс.
Автор - bmv98rus
Дата добавления - 17.10.2019 в 17:42
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Дата оплаты со сложными условиями (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!