Option Explicit

Sub Get_Value_From_Book()    
         Dim sFile As String, sh As Worksheet, ac As Long    

         With Application.FileDialog(msoFileDialogFilePicker)    
             .Filters.Clear    
             .Filters.Add "Microsoft Excel files", "*.xls"    
             .AllowMultiSelect = False    
             .InitialFileName = ThisWorkbook.Path    
             If .Show = 0 Then Exit Sub    
             sFile = .SelectedItems(1)    
         End With    

         Set sh = ActiveWorkbook.ActiveSheet    

         With Application    
             'отключаем обновление экрана - это убыстрит работу макроса    
             .ScreenUpdating = False    
             'отключаем события книги    
             .EnableEvents = False    
             'включаем ручной пересчёт формул - это убыстрит работу макроса    
             ac = .Calculation: .Calculation = xlCalculationManual    

             With GetObject(sFile).Sheets(1)    
                 .[A1].CurrentRegion.Copy sh.[H6]    
                 .Parent.Close False    
             End With    

             'возвращаем назад всё отключенное/изменённое    
             .ScreenUpdating = True    
             .EnableEvents = True    
             .Calculation = ac    
         End With    

End Sub