Option Explicit

Const ValidationList1 = "n4:n17"
Const ValidationList2 = "p4:p13"

Public Events As Boolean
       
Sub ComboChange(cb As ComboBox)
        If Not Events Then Exit Sub
        ActiveCell.Value = cb.Value
        HideCombo cb
End Sub
       
Private Sub ComboBox1_Change()
        ComboChange Me.ComboBox1
End Sub
       
Private Sub ComboBox2_Change()
        ComboChange Me.ComboBox2
End Sub
       
Sub FillCombo(cb As ComboBox, validList As String)
        Dim cell As Range
        cb.Clear
        For Each cell In Range(validList).Cells
            cb.AddItem cell
        Next
        cb.ListRows = Range(validList).Cells.Count
        cb.Value = ActiveCell.Value: cb.Font.Size = 6
End Sub
       
Sub HideCombo(cb As ComboBox)
        With cb
            .Top = 0: .Left = 0: .Width = 0: .Height = 0
        End With
End Sub
       
Sub ShowCombo(cb As ComboBox, Target As Range)
        With cb
            .Top = Target.Top: .Left = Target.Left
            .Width = Target.Width + 16: .Height = Target.Height
        End With
End Sub
       
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
       
        HideCombo Me.ComboBox1
        HideCombo Me.ComboBox2
       
        If Target.Cells.Count > 1 Then
            Exit Sub
        End If
             
        If Not (Intersect(Target, [b4:e6]) Is Nothing) Then
            Events = False
            ShowCombo Me.ComboBox1, Target
            FillCombo Me.ComboBox1, ValidationList1
            Events = True
        End If
            
        If Not (Intersect(Target, [b14:e16]) Is Nothing) Then
            Events = False
            ShowCombo Me.ComboBox2, Target
            FillCombo Me.ComboBox2, ValidationList2
            Events = True
        End If
     
End Sub