Option Explicit

Function SumByConditions(RNG As Range, rngColorFill As Range, rngColorFont As Range, ParamArray Conditions() As Variant)
'' Author:  boa
'' Written: 11.09.2019
'' Edited:
'  Description: суммирует ячейки с учетом заливки, цвета шрифта и условий >,<,=,<>
Application.Volatile True                    ' Делаем функцию волатильной, что бы она пересчитывалась при любых изменениях на листе
Dim oCell As Range
Dim dSum As Double
Dim sChar As String
Dim Condition
Dim iChar As Integer
Dim iSymbol As Integer
Dim iFulfillment As Integer
Dim ArrSymbols(): ArrSymbols = Array(">", "<", "=")                           ' массив символов сравнения
  
  For Each oCell In RNG                    ' проверяем каждую ячейку из объявленного диапазона
    If oCell.Interior.Color = rngColorFill.Interior.Color Then                ' если заливка проверяемой ячейки совпадает с цветом ячейки заданной в условии rngColorFill
      If oCell.Font.Color = rngColorFont.Font.Color Then                      ' если цвет шрифта совпадает, то идем дальше...
        iFulfillment = -1                    ' так как в функции параметры можем задавать не одним значением, а массивом (2-мя и более), то задаем значение меньше минимального индекса массива <0
        For Each Condition In Conditions                    ' перебираем все наши условия
          For iChar = 1 To VBA.Len(Condition)                    ' проверяем каждый символ начиная с 1-го на принадлежность массиву символов ArrSymbols
            sChar = VBA.Mid(Condition, iChar, 1)                    ' т.е. отрезаем по одному
            For iSymbol = LBound(ArrSymbols) To UBound(ArrSymbols)
              If sChar = ArrSymbols(iSymbol) Then Exit For                    ' если находим, то выходим из цикла и соответственно iSymbol максимум может быть равен UBound(ArrSymbols)
            Next
            If iSymbol > UBound(ArrSymbols) Then iChar = iChar - 1: Exit For  ' если после прохождения цикла iSymbol > UBound(ArrSymbols), то sChar не принадлежит массиву ArrSymbols и с символа iChar идет сравниваемое значение, соответственно мы отнимаем единицу, что бы iChar был равен последнему символу оператора сравнения
          Next
          If iChar > 0 Then sChar = VBA.Mid(Condition, 1, iChar) Else sChar = "=" ' iChar > 0, то оператор сравнения есть и мы его вырезаем, если iChar = 0, то оператора сравнения нет и соответственно значение в проверяемой ячейке должно быть равно сравниваемому значению, поэтому и присваиваем  sChar = "=". Т.е. всё как в функции "Счетеслимн"
          Select Case sChar                    ' в зависимости от символа сравнения sChar делаем сравнение.
          Case ">"
            If oCell.Value > CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1 ' если условие выполняется, то прибавляем 1
          Case "<"
            If oCell.Value < CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1
          Case ">=", "=>"
            If oCell.Value >= CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1
          Case "<=", "=<"
            If oCell.Value <= CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1
          Case "<>"
            If oCell.Value <> CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1
          Case Else
            If oCell.Value = CDbl(VBA.Mid(Condition, iChar + 1)) Then iFulfillment = iFulfillment + 1
          End Select
        Next
        If iFulfillment = UBound(Conditions) Then dSum = dSum + oCell.Value   ' если все условия из массива условий выполнились, то iFulfillment = UBound(Conditions). Если хотя бы одно условие не выполнится, то этого равенства не будет
      End If
    End If
  Next
  SumByConditions = dSum
End Function