Индекс роста цен

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Индекс роста цен (Формулы/Formulas)

Индекс роста цен

astashov_michail@tutby

Дата: Понедельник, 03.10.2022, 11:41 | Сообщение № 1

Группа: Пользователи

Ранг: Участник

Сообщений: 94

Репутация: 0 ±

Замечаний: 100% ±

2016

Всем здравствуйте. возможно ли укоротить формулу

Код

=ОКРУГЛ(C1/(((C4)+((1+C2)^(C3-5)*(C4))+((1+C2)^(C3-4)*(C4))+((1+C2)^(C3-3)*(C4))+((1+C2)^(C3-2)*(C4))+((1+C2)^(C3-1)*(C4)))/6);2)

и как-то учесть то, что если изменяется «период» с 6 лет на , например 5 лет - это автоматически учитывалось, а не вручную вводить в формулу. Заранее благодарю.

К сообщению приложен файл: 8293376.xlsx (17.7 Kb)

astashovM..

Сообщение отредактировал Serge_007 - Понедельник, 03.10.2022, 11:48

Ответить

Nic70y

Дата: Понедельник, 03.10.2022, 12:31 | Сообщение № 2

Группа: Друзья

Ранг: Экселист

Сообщений: 9006

Репутация: 2369 ±

Замечаний: 0% ±

Excel 2010

Код

=ОКРУГЛ(C1/((C4+СУММПРОИЗВ((1+C2)^(C3-СТРОКА(ДВССЫЛ("1:"&C3-1)))*C4))/C3);2)

наверное

ЮMoney 41001841029809

Ответить

scriptapplications

Дата: Понедельник, 03.10.2022, 12:38 | Сообщение № 3

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

Формулы массива ( Ctrl+Shift+Enter)

Код

=ОКРУГЛ(C1/(((C4)+СУММ(((1+C2)^(C3-СТРОКА($1:$5))*(C4))))/6);2)

Код

=ОКРУГЛ(C1/(((C4)+СУММ(((1+C2)^(C3-СТРОКА(ДВССЫЛ("$1:"&C3-1)))*(C4))))/C3);2)

К сообщению приложен файл: 8293376_2.xlsx (13.1 Kb)

Сообщение отредактировал scriptapplications - Понедельник, 03.10.2022, 12:46

Ответить

astashov_michail@tutby

Дата: Понедельник, 03.10.2022, 13:14 | Сообщение № 4

Группа: Пользователи

Ранг: Участник

Сообщений: 94

Репутация: 0 ±

Замечаний: 100% ±

2016

scriptapplications, если я изменяю «период» с 6 на другую цифру, то результат разный по двум формулам, а какая тогда формула даёт правильный результат?

astashovM..

Ответить

Gustav

Дата: Понедельник, 03.10.2022, 13:23 | Сообщение № 5

Группа: Админы

Ранг: Участник клуба

Сообщений: 2797

Репутация: 1161 ±

Замечаний: ±

начинал с Excel 4.0, видел 2.1

Если сначала немного почиститься от лишних скобок (а их там с избытком) и поменять числители и знаменатели местами (опять-таки в угоду уменьшения количества скобок), а также вспоминая кое-что (типа любое число в степени 0 = 1) из математической науки, можно слегка упростить исходную запись до такой:
[vba]

Код

=ОКРУГЛ(C1*6/C4/(
(1+C2)^(C3-6)+
(1+C2)^(C3-5)+
(1+C2)^(C3-4)+
(1+C2)^(C3-3)+
(1+C2)^(C3-2)+
(1+C2)^(C3-1)
);2)

[/vba]Ну, а дальше - "дело техники", выше уже озвученной (у меня ничего принципиально нового, только скобок поменьше):

Код

=ОКРУГЛ(C1*C3/C4/СУММ((1+C2)^(C3-СТРОКА(ДВССЫЛ("1:"&C3))));2)

Тоже формула массива, т.е. ввод по Ctrl+Shift+Enter.

МОИ: Ник, Tip box: 41001663842605

Ответить

scriptapplications

Дата: Понедельник, 03.10.2022, 13:59 | Сообщение № 6

Группа: Проверенные

Ранг: Участник

Сообщений: 68

Репутация: 12 ±

Замечаний: 0% ±

scriptapplications, правильный результат даёт вторая формула, первая только для цифры 1:5 в показателе и 6 в знаменателе.
Вторая использует перебор от 1 до C3-1 в показателе и число C3 в знаменателе, в условии прописано 6 и неясно, меняется ли это число при изменении периода (в формуле 2 это период)
Если в исходной формуле "/6" это не "/C3" то формула примет вид

Код

=ОКРУГЛ(C1/(((C4)+СУММ(((1+C2)^(C3-СТРОКА(ДВССЫЛ("$1:"&C3-1)))*(C4))))/6);2)