let
  Источник = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content],
  Отбор =
    Table.AddColumn(
      Источник,
      "Строка",
      each let
        клиент=[Номер клиента],
        закрыто=[Дата закрытия],
        тема=[Тема обращения]
      in
        Table.First(
          Table.SelectRows(
            Источник,
            each [Номер клиента]=клиент and [Дата создания]>закрыто and [Тема обращения]=тема
          )
        )
    ),
  Повтор =
    Table.FromRecords(
      Table.TransformRows(
        Отбор,
        each Record.TransformFields(
          _ ,
          let
            r = _
          in
            {
              "Повтор",
              each try
                if ((r[Строка][Дата создания]-r[Дата закрытия]))<#duration(0,48,1,0)
                then
                  "Повторное"
                else
                  "Единичное"
              otherwise
                "Единичное"
            }
        )
      )
    ),
  #"Удаленные столбцы" = Table.RemoveColumns(Повтор,{"Строка"}),
  #"Измененный тип" = Table.TransformColumnTypes(#"Удаленные столбцы",{{"Код.обращения", Int64.Type}, {"Номер клиента", Int64.Type}, {"Дата создания", type datetime}, {"Дата закрытия", type datetime}, {"Тема обращения", type text}, {"Повтор", type text}})
in
  #"Измененный тип"