Private Sub Workbook_Open()
    MyTime = Time 'присваиваем паблик переменной MyTime значение текущего времени
    Call CheckInactivity
End Sub
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    MyTime = Time   ' и при внесении изменений на листе обновляем его
End Sub
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    MyTime = Time
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
On Error Resume Next
    Application.OnTime EarliestTime:=CheckTime, _
                       Procedure:="CheckInactivity", _
                       Schedule:=False ' отключаем перезапуск макроса
End Sub

Option Explicit
Public MyTime As Date
Public CheckTime As Date

Sub CheckInactivity()
Dim MyTimer As Date: MyTimer = TimeValue("00:10:00") ' тут задайте время, через которое производятся проверки активности
With Application
    If Time > MyTime + MyTimer Then
        If Not .ThisWorkbook.ReadOnly Then 'если файл в чтении, то пусть читают
            .DisplayAlerts = 0
            .ThisWorkbook.Close True
            .DisplayAlerts = 1
        End If
    Else ' зацикливаем запуск макроса
        CheckTime = Time + MyTimer
Debug.Print CheckTime
        .OnTime EarliestTime:=CheckTime, _
                Procedure:="CheckInactivity", _
                Schedule:=True
    End If
End With
End Sub